Что такое «.\NUL»? И почему это не работает?

@masli · Регистрация: 27.03.2013

Студворк — интернет-сервис помощи студентам

Windows Batch file
1
IF NOT EXIST %work%\NUL MKDIR %work%

при запуске вот такой команды выходит диалоговое окно

Эти файлы нельзя открыть.

В чем может быть проблема, переменная %work% создана

Windows Batch file
1
set %work=%cd\windows7_x32

Dragokas · 12.04.2013, 20:42

Так Вы объясните, что пытаетесь сделать?

Что за диалоговое окно? Ничего не должно появляться по определению.

NUL или .\NUL - это устройство, которое всегда существует. Используется для перенаправления (зануления) потоков от команд.

Сообщение от masli

Bash
1
set %work=%cd\windows7_x32

это что?
Переменные задаются так:

Bash
1
set work=%~dp0windows7_x32

%~dp0 папка батника, если вопрос в этом.

IF NOT EXIST %work% ... лучше брать в кавычки во избежания проблем с пробелами IF NOT EXIST "%work%" ...

Добавлено через 5 минут
Вот еще тема: Различия перенаправлений в nul и NULL

@masli · 13.04.2013, 11:39 **[ТС]**

да переменная устанавливается так set work=%cd%\windows7_x32
ошибся, когда писал

а вот откуда информация, я пытаюсь разобрать для себя этот скрипт, не хочу бездумно копировать, а хочется дописать для удобства , объединить и копирование...

Про NULL и NUL скудно описано и сам не нашел, а эту тему , что вы по ссылке дали, нашел, но так и ничего не понял, там в основном вопросы и нет развернутых ответов на примерах.
Например как в видеоуроках Александра Пенкрата, хотелось бы в таком стиле увидеть ответ, чтоб это понять нужно сделать несколько примеров и понять как они работают, тогда понимается смысл команд и взаимодейтсвия с ними.

Windows Batch file
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
@echo off
:Start
ECHO.
ECHO Этот командный файл создает структуру папок для
ECHO работы над автоматической установкой Windows 7.
ECHO.
ECHO Для начала просто нажмите любую клавишу.
PAUSE > NUL
:CreateFolders
CLS
ECHO.
ECHO Создание папок . . .
SET work=%CD%\window7_x32
IF NOT EXIST %work%\NUL MKDIR %work%
IF NOT EXIST %work%\DVD\NUL MKDIR %work%\DVD
IF NOT EXIST %work%\ISO\NUL MKDIR %work%\ISO
IF NOT EXIST %work%\Logs\NUL MKDIR %work%\Logs
IF NOT EXIST %work%\Mount\NUL MKDIR %work%\Mount
IF NOT EXIST %work%\wim\NUL MKDIR %work%\wim
IF NOT EXIST %work%\Sandbox\NUL MKDIR %work%\Sandbox
IF NOT EXIST %work%\Updates\NUL MKDIR %work%\Updates
IF NOT EXIST %work%\xml\NUL MKDIR %work%\xml
IF NOT EXIST %work%\bootwim\NUL MKDIR %work%\bootwim
IF NOT EXIST %work%\bootwim\lp\NUL MKDIR %work%\bootwim\lp
IF NOT EXIST %work%\bootwim\mount\NUL MKDIR %work%\bootwim\mount
IF NOT EXIST %work%\mui\NUL MKDIR %work%\mui
ECHO.
ECHO Процесс создания структуры папок завершен!
pause
exit

Все это делаю на Windows 7 x 64

Dragokas · 13.04.2013, 19:59

1) Это никогда не будет работать, если допускаете опечатки:

Сообщение от masli

set work=%cd%\windows7_x32

Сообщение от masli

SET work=%CD%\window7_x32

2) Пользуйтесь данными Вам советами (использовать ~dp0 вместо %cd% (см. этот пост. Второе - использовать кавычки).

На счет Вашего замечания об информативности - я его учту и постараюсь набросать несколько примеров.

Для начала:
1. Использование NUL, чтобы спрятать сообщения.
1) Вводим команду (можно не в бат-файл, прямо в интерпретатор: Пуск -> Выполнить -> CMD)

Bash
1
pause

Получаем сообщение (это так называемый поток вывода StdOut (поток № 1)):

Нажмите любую клавишу для продолжения...

Теперь мы хотим, чтобы это сообщение не выводилось (нужно "занулить" 1-й поток):

Bash
1
pause> nul

Команда выполниться и будет все также ожидать нажатия любой клавиши, но сообщение на экран не выводится.
Эта конструкция равносильна:

Bash
1
pause 1>nul

В ней мы явно указываем, что занулить именно поток № 1.
Еще часто используется поток № 2 (StdError), куда попадают сообщения об ошибках.
Например, инсцинируем ошибку при создании каталога:

Bash
1
md c:\

Отказано в доступе.

Сообщение об ошибке зануляется так:

Bash
1
md c:\ 2>nul

Чтобы занулить все сообщения (оба потока):

Bash
1
md c:\ 2>nul 1>&2

2. Использование NUL, чтобы проверить успех операции.
Например, проверяем, что файл физически можно считать с диска:

Bash
1
copy file.avi nul&& echo Успех

Происходит имитация копирования файла file.avi, при этом file.avi считывается полностью, как при обычном копировании. && - означает что дальнейшие команды будут выполнены только при успехе операции (код возврата = 0).

Добавлено через 2 часа 58 минут
Можно переписать код так:

Bash
1
2
3
4
5
6
@echo off
set work=%~dp0windows7_x32
if not exist "%work%" md "%work%"
pushd "%work%"
for %%A in (DVD ISO Logs Mount wim Sandbox Updates xml bootwim\lp bootwim\mount mui) do >nul md "%%A"
popd

@masli · 13.04.2013, 23:41 **[ТС]**

Bash
1
md c:\2>nul 1>&2

Хотел бы разобрать это.

1.При выполнении команды

Bash
1
md c:\

появляется ошибка, но Оператор перенаправления >

Bash
1
2>nul

обнуляет сообщение, то есть не выводит на экран , при этом 2 - означает вывод потока ошибок

STDERR имеет значение 2 и означает: Ошибка вывода в окно командной строки
STDOUT имеет значение 1 и означает : Вывод результата(успешного выполнения команды) в окно командной строки

По умолчанию, входные данные команды (дескриптор STDIN - Ввод с клавиатуры имеет значение 0) отсылаются с клавиатуры интерпретатору команд Cmd.exe, далее Cmd.exe отправляет выходные данные команды (дескриптор STDOUT) в окно командной строки.

Затем поток вывода STDOUT имеет значение 1 несет в себе информацию что никакой ошибки нет , в этот момент Оператор перенаправления >& Считывает данные на выходе одного дескриптора как входные данные для другого дескриптора, а именно передает 0 в поток STDERR , ну и как следствие опять же на экране нет ошибок

Дескриптор - местоположение потоков ввода и вывода называется .

Правильно ли я разобрал пример?

И еще , не могу понять это просто пример или реально он как то лучше выполняет обнуление , иначе говоря

Bash
1
md c:\2>nul

- это же выполняет то же обнуление.

Какие еще два потока обнулять, ведь на экране я вижу один поток - это сообщение об ошибке, поэтому и не пойму к чему этот пример

Bash
1
md c:\2>nul 1>&2

Dragokas · 14.04.2013, 00:20

Сообщение от masli

обнуляет сообщение, то есть не выводит на экран , при этом 2 - означает вывод потока ошибок

не обнуляет, а зануляет. Ошибка все равно есть.
Другими словами - перенаправляет поток на устройство NUL.

Сообщение от masli

а именно передает 0 в поток STDERR , ну и как следствие опять же на экране нет ошибок

0 - это входящий поток (например, ввод с клавиатуры). Он здесь не при чем.
2>nul 1>&2
Другими словами: происходит конкатенация потока № 1 с потоком № 2. Затем поток № 2 "зануляется".

Сообщение от masli

лучше выполняет обнуление

Лучше ничего выполнять он не будет, просто неудачный пример. Есть команды, которые используют оба потока.
Зато при большом количестве однотипных операций, которые выводят сообщения на экран, это может ускорить процесс. Вывод на экран занимает время.
А в Вашем случае нужен только из эстетических интересов.

Добавлено через 2 минуты

Сообщение от masli

md c:\2>nul

да, но лучше так не писать, ибо не понятно, что здесь происходит.
Интерпретатор тоже может прочесть это по-разному в вариациях с другими командами. Отступайте пробелом.

@masli · 14.04.2013, 20:26 **[ТС]**

Bash
1
set work=%~dp0windows7_x32

– установить переменную по пути Текущий_каталог\windows7_x32

%~dp0 - обозначение текущего каталога

Bash
1
if not exist "%work%" md "%work%"

- если не существует переменная "%work%" создать переменную "%work%", кавычки нужно для того, если в пути переменной кириллица и (или)пробелы между названиями, так как пробел означает что за ним начинается другая переменная.
Таким образом в папке, откуда запущен командный файл(которая является текущей и обозначена %~dp0 ), создается каталог windows7_x32

Bash
1
pushd "%work%"

- Каталог, который следует назначить текущим.
Какой каталог? Их два : 1-й это тот в котором создан каталог windows7_x32
2-й каталог это windows7_x32, в котором собственно и создаются остальные каталоги

Bash
1
for %%A in (DVD ISO Logs Mount wim Sandbox Updates xml bootwim\lp bootwim\mount mui) do >nul md "%%A"

- обозначает, что для переменной %%A ( символ двойного процента %% - это использование написания переменной в командных файлах, при написании просто в строке интерпретатора используется символ одного %) в наборе каталогов (перечисленных в скобках) выполнить команды:

1. Перенаправить поток вывода в NUL - Зачем? Что это дает, я делал с разными параметрами с оператором > и без, различия не увидел
2. Создать каталоги которых нет в наборе

Popd - переходит в каталог который был назначен текущим командой PUSHD и сохранен текущим,
А как же он без этих команд станет не текущим? Ведь командный файл пишется так что если нужно из текущего каталога не выходят во время работы командного файла, вообщем запутался

И зачем они применили такую конструкцию

Bash
1
"%work%"\Nul

, что значит обратный слэш в таком сочетании с Nul - не понятно…

Dragokas · 14.04.2013, 21:09

Сообщение от masli

если не существует переменная "%work%"

Если не существует папка, заданная в значении переменной...

Сообщение от masli

если в пути переменной кириллица

Кавычки от этого не помогут.
С кириллицей и так по-умолчанию, работает нормально, если только Вы вручную не задаете название папки кириллицей - тогда бат-файл нужно сохранять в кодировке DOS (OEM-866).
Или если попадуться укр. и др. символы такие, как ї, тогда в начале бат-файла нужно прописывать команду chcp 1251

Сообщение от masli

- Каталог, который следует назначить текущим.

Это не совсем верная формулировка. Текщим - является каталог, в котором Вы сейчас находитесь.
Прочитайте справку по pushd /?
popd - использовал чисто из здравой логики. Можно не писать. Переходит в каталог, который запомнила команда Pushd перед переходом в новый каталог.

Сообщение от masli

%% - это использование написания переменной в командных файлах

Это так называемая переменная цикла.

Сообщение от masli

. Перенаправить поток вывода в NUL - Зачем?

Если каталог уже существует, на экран будет выведена ошибка.

Сообщение от masli

2. Создать каталоги которых нет в наборе

Такого кода я не писал. Это Вы за меня додумали.

Сообщение от masli

И зачем они применили такую конструкцию

Не знаю.

@masli · 14.04.2013, 21:57 **[ТС]**

Сообщение от Dragokas

Это не совсем верная формулировка. Текщим - является каталог, в котором Вы сейчас находитесь.
Прочитайте справку по pushd /?

Да текущий каталог в данном случае windows7_x32,так как ради него и создана переменная "%work%", понял.
pushd делает данный каталог текущим

Сообщение от Dragokas

.
Если каталог уже существует, на экран будет выведена ошибка.

Как я понимаю перенаправление вывода команды For (если набор каталогов существует) в ноль, то есть в отсутствие вывода сообщений что каталоги уже существуют ...

Пробовал что так

Bash
1
2
3
4
@Echo off
for %%A in (DVD ISO Logs Mount wim Sandbox Updates xml bootwim\lp bootwim\mount mui) do >nul md %%A
pause
echo on

что так

Bash
1
2
3
4
@Echo off
for %%A in (DVD ISO Logs Mount wim Sandbox Updates xml bootwim\lp bootwim\mount mui) [COLOR="Magenta"]do[/COLOR] md %%A
pause
echo on

Все равно идет вывод Подпапка или файл .... уже существует.

@Eva Rosalene · 14.04.2013, 23:09

Сообщение от masli

Bash
1
2
3
4
@Echo off
for %%A in (DVD ISO Logs Mount wim Sandbox Updates xml bootwim\lp bootwim\mount mui) do md %%A 
pause 
echo on

Значит, эти папки уже существуют. Чтобы занулить вывод ошибок надо:

Bash
1
md Example >nul 2>nul

Просто stdout (вывод в консоль) и stderr (вывод ошибок в консоль) - 2 разных потока, а сообщение о существовании папок выводится именно в stderr. А зануление stderr - это и есть 2>nul

@masli · 15.04.2013, 10:14 **[ТС]**

Нашел для себя вот что про параметр %~dp0
FAQ по файлам BAT/CMD

Иногда сценарию надо знать полный путь к себе самому и/или к каталогу, в котором он находится. Это может понадобиться по разным причинам. Например, он должен достать из системы контроля версий исходники в каталог <script-dir>/src рядом с собой. Или, запускаются тесты из каталога <script-dir>/tests, и перед их запуском надо добавить каталог <script-dir>/bin в переменную PATH.

Можно, конечно, рассчитывать на то, что командный файл был вызван из того же каталога, где он находится, и тогда в качестве вышеупомянутого <script-dir> можно использовать переменную окружения %CD% - полный путь к текущему каталогу. Однако любые допущения в нашем деле недопустимы (хороший каламбур, однако!). Поэтому приведу более надежное решение.

Прежде всего, вспоминаем, что переменная %0 в bat-файле соответствует нулевому аргументу командной строки, т.е. имени самого файла. После этого читаем скудную документацию для команды call:

Bash
1
call /?

Форум

и обнаруживаем, что при использовании нумерованных переменных %0-%9 можно использовать некоторые модификаторы:

Code
1
2
~dI       - переменная I раскрывается в букву диска
~pI       - переменная I раскрывается в путь

где I - это какая нибудь переменная %1 или %2 или %3 и т.д.

Форум

%~d1 - разворачивает %1 в букву диска
%~p1 - разворачивает %1 в путь

Справка

При объединении модификаторов получаются комбинированные
результаты::

Code
1
%~dp1       - переменная %1 заменяется только на имя диска и путь

Таким образом, правильным будет использовать в качестве тега <script-dir> сочетание %~dp0, которое будет раскрыто в полный путь к каталогу, где находится сценарий.

@Eva Rosalene · 15.04.2013, 19:02

Если батник вызван из сетевой папки, то при попытке cd %~dp0 папка сменится на катлог Windows

Charles Kludge · 15.04.2013, 20:52

Сообщение от FraidZZ

то при попытке cd %~dp0 ...

...ничего не произойдёт.

Code
1
2
3
4
Windows Registry Editor Version 5.00
 
[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Command Processor]
"DisableUNCCheck"=dword:00000001

By default, a command box (cmd.exe) will check if the current directory is an UNC path (\\myserver\path) and if this is the case, it will write an error message and change the path to C:\.

Thus, it is not possible to use UNC paths in a command box which can be very annoying.

When this option is turned on, you can use UNC paths as the current directory and you will also no longer get an error message when the command box starts from a UNC path.

@gimntut · 18.04.2013, 22:20

Сообщение от masli

И зачем они применили такую конструкцию

Bash
1
"%work%"\Nul

Ни когда подобного не видел. Очень оригинально.
В данном скрипте предполагается, что Exist не всегда адекватно срабатывает на проверку папок, поэтому должна делаться проверка на наличие файла.
Любой файл в Windows ищется в 2 этапа. Сначала ищется папка в которой лежит файл, а потом уже сам файл.
Если папка не существует, то ОС даже не будет пытать искать файл в папке. В результате exist сообщит, что файл не найден. А вот если папка существует, то начинается проверка на наличие в папке файла NUL, а этот файл как и PRN и COM1 существует всегда.
Попробуй выполнить в командной строке следующие команды по отдельности:

Bash
1
2
if exist ..\prn @echo OK
if exist ..\prnfile @echo OK

Dragokas · 18.04.2013, 22:35

Забавно. А я вот просто так проверял:

Bash
1
if exist "%work%\" @echo OK

@gimntut · 18.04.2013, 22:45

Сообщение от Dragokas

Забавно. А я вот просто так проверял:

Bash
1
if exist "%work%\" @echo OK

В Delphi есть одноимённая команда, которая не работает на папках.
Это одна из возможных причин заблуждения.
В любом случае, проверка NUL по полному пути это очень интересный приём.
Лично я не знал, что так можно.

@Smitis · 30.04.2013, 17:54

Добавлю свои пять копеек

Сообщение от gimntut

В Delphi есть одноимённая команда, которая не работает на папках.
Это одна из возможных причин заблуждения.
В любом случае, проверка NUL по полному пути это очень интересный приём.
Лично я не знал, что так можно.

Причина заблуждения - историческая. Дело в том, что под DOS и Win9x нельзя было проверить существование папки через if exist просто указав её имя. Но работал приём с проверкой файла NUL в папке. А вот в линейке NT совсем другой подход. Честно говоря, я уже подзабыл, как там это работало с длинными именами в Win9x, но в NT (NT4,2000,XP,2003,etc.) работает только если имя не заключено в кавычки.

Например, проверка

Bash
1
if exist "C:\Program Files\nul" echo exist

не пройдёт, зато пройдёт по короткому имени

Bash
1
if exist c:\progra~1\nul echo exist

Или, например, пройдёт проверка

Bash
1
if exist c:\programdata\nul echo exist

Имхо, проверку на NUL ставят, типа, "так в детстве научили" или просто тупо переносят старые батники под CMD не думая.

@Семёнычев Роман · 14.02.2016, 14:05

увидел в одном батнике конструкцию

Windows Batch file
1
_команда_ > nul:

проверил, работает. просто нул с двоеточием. просто для информации

Dragokas · 14.02.2016, 17:38

Семёнычев Роман, интересное наблюдение.
Похоже, что знак ":" в данном случае воспринимается как разделитель имени файла и имени потока.

Тем не менее, я попробовал такой батник:

Windows Batch file
1
@echo "%1" >&2

выполнить с разным набором разделителей и файлами NUL (устройство NUL), и NULL (обычное имя файла):

C:\Users\Alex>t >NUL:1,World
"World"

C:\Users\Alex>t >NULL:1,World
"World"

C:\Users\Alex>t >NUL:1:World
""

C:\Users\Alex>t >NULL:1:World
Синтаксическая ошибка в имени файла, имени папки или метке тома.

У первых двух результат ожидаемый: разделитель передает слово "World" как 2-й аргумент.
А вот разницу в последних двух вариантах я не могу объяснить. У кого есть идеи?

@Семёнычев Роман · 21.02.2016, 08:25

у тебя перед nul нет пробела. не знаю, важно ли это

Новые блоги и статьи Все статьи Все блоги /
сукцессия микоризы: основная теория в виде двух уравнений. anaschu 11.01.2026 https:/ / rutube. ru/ video/ 7a537f578d808e67a3c6fd818a44a5c4/	WordPad для Windows 11 Jel 10.01.2026 WordPad для Windows 11 — это приложение, которое восстанавливает классический текстовый редактор WordPad в операционной системе Windows 11. После того как Microsoft исключила WordPad из. . .	Classic Notepad for Windows 11 Jel 10.01.2026 Old Classic Notepad for Windows 11 Приложение для Windows 11, позволяющее пользователям вернуть классическую версию текстового редактора «Блокнот» из Windows 10. Программа предоставляет более. . .	Почему дизайн решает? Neotwalker 09.01.2026 В современном мире, где конкуренция за внимание потребителя достигла пика, дизайн становится мощным инструментом для успеха бренда. Это не просто красивый внешний вид продукта или сайта — это. . .
Модель микоризы: классовый агентный подход 3 anaschu 06.01.2026 aa0a7f55b50dd51c5ec569d2d10c54f6/ O1rJuneU_ls https:/ / vkvideo. ru/ video-115721503_456239114	Owen Logic: О недопустимости использования связки «аналоговый ПИД» + RegKZR ФедосеевПавел 06.01.2026 Owen Logic: О недопустимости использования связки «аналоговый ПИД» + RegKZR ВВЕДЕНИЕ Введу сокращения: аналоговый ПИД — ПИД регулятор с управляющим выходом в виде числа в диапазоне от 0% до. . .	Модель микоризы: классовый агентный подход 2 anaschu 06.01.2026 репозиторий https:/ / github. com/ shumilovas/ fungi ветка по-частям. коммит Create переделка под биомассу. txt вход sc, но sm считается внутри мицелия. кстати, обьем тоже должен там считаться. . . .	Расчёт токов в цепи постоянного тока igorrr37 05.01.2026 / * Дана цепь постоянного тока с сопротивлениями и напряжениями. Надо найти токи в ветвях. Программа составляет систему уравнений по 1 и 2 законам Кирхгофа и решает её. Последовательность действий:. . .

Что такое «.\NUL»? И почему это не работает?

Решение

Решение

@Eva Rosalene Модератор 5241 / 2115 / 416 Регистрация: 06.01.2013 Сообщений: 4,846
	15.04.2013, 19:02
	Если батник вызван из сетевой папки, то при попытке cd %~dp0 папка сменится на катлог Windows 0

@Семёнычев Роман 12 / 3 / 0 Регистрация: 04.05.2011 Сообщений: 17
	21.02.2016, 08:25
	у тебя перед nul нет пробела. не знаю, важно ли это 0