Проверка свободного места на диске в cmd

Free space C:  128 Gb of  160 Gb
Free space D:  410 Gb of  500 Gb
Free space E:  16 Gb of  20 Gb
Free space F:  1038 Gb of  1479 Gb

@echo off
setlocal enableextensions enabledelayedexpansion
echo.>%0.txt
 for %%j in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
 rem echo %%j
 
 
set sFreeSize=0
set /a c=0
for /f "skip=1 tokens=2 delims=:" %%i in ('fsutil volume diskfree %%j:') do (
  set /a c+=1
  rem echo !c! %%i
  if !c!==1 set sFreeSizeOf=%%i
  if !c!==2 set sFreeSize=%%i
)
 
if NOT !sFreeSize!==0 echo Free space %%j: !sFreeSize:~0,-9! Gb of !sFreeSizeOf:~0,-9! Gb>>%0.txt
rem :~0,-9
 )
endlocal

@echo off
echo.>%0.txt
setlocal enableextensions enabledelayedexpansion
set err=100
for %%j in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
 rem echo %%j
 
  set sFreeSize=0
  set sFreeSizeOf=0
  set /a c=0
  for /f "skip=1 tokens=2 delims=:" %%i in ('fsutil volume diskfree %%j:') do (
    set /a c+=1
    rem echo !c! %%i
    if !c!==1 set sFreeSizeOf=%%i
    if !c!==2 set sFreeSize=%%i
  )
 
  if NOT !sFreeSize!==0 if NOT !sFreeSizeOf!==0 (
    set /A Free=!sFreeSize:~0,-9!
    set /A Size=!sFreeSizeOf:~0,-9!
    set /A Procent=!Free!*100/!Size!
    set ah= 
    if !Procent! LSS 20 (
      set ah=***ACHTUNG*** 
 
      if !Procent! LSS !err! set err=!Procent!
    )
    echo !ah!Free space %%j: !Procent!%%. Free !Free! Gb of !Size! Gb >>%0.txt
  )
 
 
)
 
exit /b !err!
endlocal

@echo off
echo.>%0.txt
setlocal enableextensions enabledelayedexpansion
set err=100
 
for /f "skip=1 tokens=1-3" %%i in ('2^>nul ^
WMIC LogicalDisk ^
WHERE "DriveType='3'" ^
GET FreeSpace^, Name^, Size^') do (
 
  set sFreeSize=%%i
  set sFreeSizeOf=%%k
 if NOT 1%%j==1 (
    echo %%j %%i %%k
    set /A Free=1
    set /A Free=!sFreeSize:~0,-9!
    set /A Size=!sFreeSizeOf:~0,-9!
    set /A Procent=!Free!*100/!Size!
    set ah= 
echo Free=!Free! Size=!Size! Procent=!Procent!
    if !Procent! LSS 20 (
      set ah=***ACHTUNG*** 
      if !Procent! LSS !err! set err=!Procent!
    )
    echo !ah!Free space %%j: !Procent!%%. Free !Free! Gb of !Size! Gb >>%0.txt
  )
 
)
type %0.txt
rem pause
exit /b !err!
endlocal

@echo off
setlocal enableextensions enabledelayedexpansion
for /f "skip=1 tokens=1-3" %%i in ('2^>nul ^
WMIC LogicalDisk ^
WHERE "DriveType='3'" ^
GET FreeSpace^, Name^, Size^') do (
set sFreeSize=%%i
set sFreeSizeOf=%%k
if NOT 1%%j==1 (
set /A Free=1
set /A Size=!sFreeSizeOf:~0,-3!/1024/1024
set /A prc=!Size!/100*3
set /A Size=!Size!-!prc!
set /A Free=!sFreeSize:~0,-3!/1024/1024
set /A prcc=!Free!/100*3
set /A Free=!Free!-!prcc!
set /A Procent=!Free!*100/!Size!
set /A a+=!Size!
set /A al+=!free!
set /A all+=!Procent!
echo Свободно %%j !Procent!%%. !Free! Гб из !Size! Гб
))
echo Всего %a% Гб, свободно %al% Гб (%all%%%)
pause >nul
exit

@echo off
chcp 65001 >nul& color f9
setlocal enableextensions enabledelayedexpansion
if "%~1"=="" (echo CreateObject^("Shell.Application"^).ShellExecute WScript.Arguments^(0^),"1","","runas",1 >"%~dp0Arun.vbs"& cscript //nologo "%~dp0Arun.vbs" "%~f0"& del /f /q "Arun.vbs"& exit)
echo Copyright © Китаец228& timeout 2 /nobreak >nul
:ag
set a=0
for %%h in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (call :chk "%%h")
cls
for /l %%h in (1,1,!a!) do (echo !a%%h!)
choice /c x /n /t 5 /d x >nul
goto ag
:chk
set tm=0& set b=0& set c=0
for /f "usebackq tokens=2 delims=:" %%h in (`fsutil volume diskfree %~1:\`) do (set wok=%%h
if not "!wok:~0,2!"=="  " (if "!tm!"=="0" (set tm=1& set b=!wok:~1!) else (set tm=0& set c=!wok:~1!)))
if not "!b!"=="0" (if not "!c!"=="0" (call :cal "((!b!/1024)/1024)/1024" "b"& call :cal "((!c!/1024)/1024)/1024" "c"
set db=!b:,=.!& set dc=!c:,=.!& call :cal "(100*!db!)/!dc!" "prb"& call :remzn "prb"& call :remzn "b"& call :remzn "c"
set /a a+=1& set a!a!=Disk %~1: Free !b! Gb ^(!prb! %%%^) of !c! Gb))
exit /b
:cal
echo res=Eval("%~1")>sh& echo WScript.Echo res>>sh
for /f "usebackq tokens=*" %%h in (`cscript /nologo /e:vbscript "sh"`) do (set %~2=%%h)
del /f /q "sh"
exit /b
:remzn
set remznsh=3
set wok=!%~1!
:remznag
if "!wok:~0,1!"=="," (set wok=!%~1!& set %~1=!wok:~0,%remznsh%!& exit /b) else (set wok=!wok:~1!& set /a remznsh+=1)
goto remznag

nircmd win hide title "%comspec%"
@echo off
set "mailsender=ПУТЬ\mailsend1.19.exe"
set "smtpserver=smtp.gmail.com"
set "smtpport=465"
set "smtpuser=ЛОГИН ОТ КОГО@gmail.com"
set "smtppwd=ПАРОЛЬ ПОЧТЫ"
set "smtpsender=ЛОГИН КОМУ@gmail.com" 
set "subject=ЗАГОЛОВОК ПИСЬМА"
set "body=СООБЩЕНИЕ В ТЕЛЕ ПИСЬМА"
 
"%mailsender%" ^
+cc +bc -q ^
-user "%smtpuser%" ^
-pass "%smtppwd%" ^
-t "%smtpuser%" ^
-f "%smtpsender%" ^
-auth -smtp "%smtpserver%" ^
-ssl -port "%smtpport%" ^
-sub "%subject%" ^
-M "%body%"
exit

nircmd win hide title "%comspec%"
@echo off
>nul chcp 1251
set "mailsender=ПУТЬ\mailsend1.19.exe"
set "smtpserver=smtp.gmail.com"
set "smtpport=465"
set "smtpuser=ЛОГИН ОТ КОГО@gmail.com"
set "smtppwd=ПАРОЛЬ ПОЧТЫ"
set "smtpsender=ЛОГИН КОМУ@gmail.com" 
set "subject=ЗАГОЛОВОК ПИСЬМА"
set "body=СООБЩЕНИЕ В ТЕЛЕ ПИСЬМА"
 
"%mailsender%" ^
-cs 1251 +cc +bc -q ^
-user "%smtpuser%" ^
-pass "%smtppwd%" ^
-t "%smtpuser%" ^
-f "%smtpsender%" ^
-auth -smtp "%smtpserver%" ^
-ssl -port "%smtpport%" ^
-sub "%subject%" ^
-M "%body%"
exit

@Echo Off &Cls
 
    Set /A Space=21475 &Rem 20Г=21474'836480 байт усекли на 6 разрядов
 
    FOR /F "tokens=1,2* delims=: " %%i In ('"WMIC LogicalDisk where DriveType=3 Get FreeSpace, Name, Size |Find ":""') DO (
        Set "S=%%i
        Call Set /A Fsize%%j=%%S:~0,-6%%
    )
    Echo Free disk space Mbyte bytes on disks:
    Set "Fsize"
 
    Set "Disk="
    If "%Disk%"=="" If Not "%FsizeE%"=="" If %FsizeE% GTR %Space% Set "Disk=E" 
    If "%Disk%"=="" If Not "%FsizeD%"=="" If %FsizeD% GTR %Space% Set "Disk=D" 
    If "%Disk%"=="" If Not "%FsizeC%"=="" If %FsizeC% GTR %Space% Set "Disk=C" 
 
    If "%Disk%"==""  (Echo There is not enough disk space !!! &Pause &Exit /B 2)
 
    Echo. &Call Echo Here we make the necessary utility on the %Disk% (FreeSpace=%%Fsize%Disk%%% Mbyte)
Pause
Exit /B