Копирование с выводом списка и выбора конкретного файла

@echo off
set "source=C:\test\source"
set "destination=C:\test\destination"
powershell -executionpolicy bypass -command "get-childitem '%source%' -file | where {$_.extension -eq '.conf'} | foreach -begin {$index=1; $hashtable=@{}} -process {"""$($index). $($_.name)"""; $hashtable.add([string]$index, $_); $index++}; $request=read-host 'Введите номер файла, который нужно скопировать'; copy-item $hashtable[$request].fullname '%destination%'"
pause
exit

@echo off
chcp 65001 > nul
setlocal EnableDelayedExpansion
 
:: %~dp0 - папка, где лежит батник (включая конечный слеш)
set "INPUT=%~dp0in"
set "OUTPUT=%~dp0out"
 
set len=1
for /f "tokens=*" %%i in ('dir /b "%INPUT%"') do (
    set "file_!len!=%%i"
    set /a len+=1
)
set /a len-=1
 
for /l %%i in (1,1,%len%) do echo %%i. !file_%%i!
 
set /p "i=Введите номер файла: "
copy "%INPUT%\!file_%i%!" "%OUTPUT%\!file_%i%!" > nul

@Echo Off &Cls &SetLocal
    Set "Ext=.conf"
    Set "destination=Z:\test\destination"
 
    Pushd "%~dp0"
 
    For /f "tokens=2 delims=:" %%i In ('Chcp') Do (Set /A sPrevCP=%%i &>nul Chcp 1251)
 
    For /f "usebackq delims=" %%i in (
        `@"%systemroot%\system32\mshta.exe" "about:<FORM><INPUT type='file' name='qq'></FORM><script>document.forms[0].elements[0].click();var F=document.forms[0].elements[0].value;try {new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(F)};catch (e){};close();</script>" ^
        1^|more`
    ) Do (Set "sFileName=%%i" &Set "eFileName=%%~xi")
 
    >nul Chcp %sPrevCP%
 
    If Defined sFileName (
        If /I Not "%Ext%"=="%eFileName%" (Echo Selected "%sFileName%" not "*%Ext%" file) Else (
            Echo Copy "%sFileName%" "%destination%\
            Copy "%sFileName%" "%destination%\")
    ) Else (
            Echo File not selected
    )
    Popd &EndLocal
Pause
Exit /B 0

@Echo Off &Cls &SetLocal
    Set "destination=Z:\test\destination"
 
    Pushd "%~dp0"
    Set "source=Z:\test\source\*.conf"
rem Set "source=source\*.conf"
rem Set "source=*.conf"
 
    If Not Exist "%source%" (Popd &Echo Source files "%source%" not found &Pause &Exit /B)
 
    Set /A i=0
    For %%f In ("%source%") Do (
        Set /A i+=1
        Call Echo %%i%% = "%%~nxf"
        Call Set "@@%%i%%=%%f"
    )
    Echo. &Set /P N=Enter file number 1^<=N^<=%i% ^>
    Call Set "File=%%@@%N%%%"
    If Defined File (
        Echo Copy "%File%" "%destination%\
        Copy "%File%" "%destination%\"
    ) Else (
        Echo !!! The entered number value "%N%" is incorrect 
    )
    Popd &EndLocal
Pause
Exit /B 0