Сравнение старого URL с новым, замена по совпадающему слову (значению) с выводом в новый файл

@echo off
setlocal EnableDelayedExpansion
pushd "%~dp0"
 
copy nul result.txt > nul
 
for /f "tokens=*" %%i in (old.txt) do (
    set "str=%%i"
    set "strp=!str:https=" "!"
    set counter=0
    for %%j in ("!strp!") do (
        if !counter!==0 set "attr=%%~j"
        if !counter!==1 (
            set "link=https%%~j"
            call :get_lss_parts "!link!" 2 plink
            set counter2=0
            for /f "tokens=*" %%k in (new.txt) do (
                call :get_lss_parts "%%k" 2 pk
                call :get_lst_parts "%%k" 2 pklstp
                if "!plink!"=="!pk!" (
                    echo.!attr!!plink!/!pklstp!>> result.txt
                ) else (
                    if !counter2!==0 ( echo.!attr!!link!>> result.txt )
                )
                set /a counter2+=1
            )
        )
        set /a counter+=1
    )
)
 
popd
 
exit /b
 
:str_len
    set _len=0
    set "__str=%~1"
    
    :_str_len_loop
        set "__str=%__str:~1%"
        set /a _len+=1
    if not "%__str%"=="" goto _str_len_loop
    
    set "%~2=%_len%"
goto :eof
 
:str_count
    set _count=0
    set "_str=%~1"
    call :str_len "%_str%" _len
    
    for /l %%i in (0,1,%_len%) do (
        echo.!_str! | findstr "^%~2" >nul 2>nul
        if !ERRORLEVEL!==0 set /a _count+=1
        set "_str=!_str:~1!"
    )
    set "%~3=%_count%"
goto :eof
 
:get_lss_parts
    setlocal
    set "str=%~1"
    call :str_count "%str%" / count
    set "strp=%str:/=" "%"
    set counter=0
    set /a countm2=count-%~2
    for %%i in ("!strp!") do (
        if !countm2! geq !counter! set "pstr=!pstr!/%%~i"
        set /a counter+=1
    )
    set "pstr=%pstr:~1%"
    endlocal & set "%~3=%pstr%"
goto :eof
 
:get_lst_parts
    setlocal
    set "str=%~1"
    call :str_count "%str%" / count
    set "strp=%str:/=" "%"
    set counter=0
    set /a countm2=count-%~2
    for %%i in ("!strp!") do (
        if !countm2! lss !counter! set "pstr=!pstr!/%%~i"
        set /a counter+=1
    )
    set "pstr=%pstr:~1%"
    endlocal & set "%~3=%pstr%"
goto :eof

@Echo Off &cls
>nul Chcp 1251
    Set "FileInOld=Z:\Box_In\Old.txt"
    Set "FileInNew=Z:\Box_In\New.txt"
    Set "FileOut=Z:\Box_Out\result.txt"
    Set /A M=3
 
    2>nul Del "%FileOut%"
    If Not Exist "%FileInOld%" (Echo "%FileInOld%" not found &Pause &Exit /B 2) 
    If Not Exist "%FileInNew%" (Echo "%FileInNew%" not found &Pause &Exit /B 2) 
 
    For /F "usebackq tokens=1* delims=:" %%f In (`2^>nul More "%FileInOld%"`) Do (
        Call :Pars "%%g" "/%%~nxg" "All" "Part"
        For /L %%i In (2,1,%M%) Do Call:Pars "%%All%%" "/%%Part%%" "All" "Part"
        Set "Out=%%f:%%g"
        For /F "usebackq Skip=2 tokens=2 delims=:" %%n In (`2^>nul Call Find /I "/%%Part%%/" "%FileInNew%"`) Do Set "Out=%%f:%%n"
        Call Echo %%Out%%>>"%FileOut%"
    )
Pause
Exit /B
 
:Pars
    Set "A=%~p1"
    Set "A=%A:~0,-1%"
    Set "A=//%A:/=\%"
    Set "%~3=%A%" &Set "%~4=%~nx1"
Exit /B