Поиск и перемещение файлов на сетевой диск

@echo off
setlocal EnableDelayedExpansion
 
for /f "skip=1" %%i in ('wmic LOGICALDISK WHERE VolumeName^="TFATSNYATO" GET Name') do set "Drive=%%i" & goto GotDrive
 
:GotDrive
for /f "tokens=*" %%i in ('dir /b /s "%Drive%\DCIM\*.jpg"') do (
    call :GetCreationDate "%%~i" Date
    set Day=!Date:~0,2!
    set Month=!Date:~3,2!
    set Year=!Date:~6,4!
    echo F | xcopy /y "%%~i" "\\10.10.0.27\base\%ComputerName%\!Year!\!Month!\!Day!\%%~nxi"
    del "%%~i" &rem Если не нужно удалять оригинальный файл, эту строку следует убрать
)
 
exit /b
 
:GetCreationDate [file] [outvar]
    for /f "tokens=1,2 skip=5" %%i in ('dir /-b "%~1" /t:c') do set "%~2=%%i %%j" & goto :eof
goto :eof

@Echo Off &Cls
>nul Chcp 1251
    Set "VName=Transend32"
    Set "Share=\\192.168.100.23\Test2"
    Set "Ffrom=DSIM"
    Set "Mask=*.jpg"
rem Set "Mask=*.jpg *.png"
 
    If Not Exist "%Share%\" (Echo Folder "%Share%\" not found &Pause &Exit /B 2)
 
    Set "Name="
    For /F %%N In ('"WMIC LogicalDisk Where VolumeName="%VName%" GET Name|Find ":""') Do Set "Name=%%N"
    If Not Defined Name (Echo Volume "%VName%" not found &Pause &Exit /B 2)
    If Not Exist "%Name%\%Ffrom%\" (Echo Folder "%Name%\%Ffrom%" not found &Pause &Exit /B 2)
 
    Call :MyMove "%Name%\%Ffrom%"
    For /F "usebackq delims=" %%d In (`2^>nul Dir "%Name%\%Ffrom%\*.*" /S /B /A:D ^|Sort /R`) Do Call :MyMove "%%d"
Pause
Exit /B 0
 
:MyMove
Echo +++ %1
    Pushd %1
        For %%f In (%Mask%) Do (
            Set "P=%%~tf"
            Call Set "P=%Share%\%ComputerName%\%%P:~6,4%%\%%P:~3,2%%\%%P:~0,2%%"
            2>nul Call Md "%%P%%" 
            
            >nul Call Move /Y "%%f" "%%P%%\"
rem         Echo F|Call xcopy /D "%%f" "%%P%%\">nul
        )
    Popd
rem 2>nul Rd %1
Exit /B 0

@Echo Off &Cls
>nul Chcp 1251
    Set "VName=Transend32"
    Set "Share=\\192.168.100.23\Test2"
    Set "Ffrom=DSIM"
    Set "Mask=*.jpg"
    Set "Mask=*.jpg *.png"
 
    If Not Exist "%Share%\" (Echo Folder "%Share%\" not found &Pause &Exit /B 2)
 
    Set "Name="
    For /F %%N In ('"WMIC LogicalDisk Where VolumeName="%VName%" GET Name|Find ":""') Do Set "Name=%%N"
    If Not Defined Name (Echo Volume "%VName%" not found &Pause &Exit /B 2)
    Pushd "%Name%\%Ffrom%" || (Echo Folder "%Name%\%Ffrom%" not found &Pause &Exit /B 2)
 
    For /F "usebackq delims=" %%f In (`2^>nul Dir %Mask% /S /B /A:-D ^|Sort /R`) Do (
        Set "P=%%~tf"
        Call Set "P=%Share%\%ComputerName%\%%P:~6,4%%\%%P:~3,2%%\%%P:~0,2%%"
        2>nul Call Md "%%P%%" 
            
        >nul Call Move /Y "%%f" "%%P%%\"
rem     Echo F|Call xcopy /D "%%f" "%%P%%\">nul
    )
    Popd
Pause
Exit /B 0

@Echo Off &Cls
>nul Chcp 1251
    Set "VName=Transend32"
    Set Share="\\192.168.100.23\Test2" "D:\CMD_Forum\Box_Out"
    Set "Ffrom=DSIM"
    Set "Mask=*.jpg *.png"
    
    Set "SS="&Set /A L=0
    For %%s In (%Share%) Do If Not Exist "%%~s\" (Echo Folder "%%~s" not found) Else (Set /A L+=1 &Call Set SS=%%SS%%%%s )
    If %L% Equ 0 (Echo Folder^(s^) %Share% not found &Pause &Exit /B 2)
 
    Set "Name="
    For /F %%N In ('"WMIC LogicalDisk Where VolumeName="%VName%" GET Name|Find ":""') Do Set "Name=%%N"
    If Not Defined Name (Echo Volume "%VName%" not found &Pause &Exit /B 2)
    Pushd "%Name%\%Ffrom%" || (Echo Folder "%Name%\%Ffrom%" not found &Pause &Exit /B 2)
 
    For /F "usebackq delims=" %%f In (`2^>nul Dir %Mask% /S /B /A:-D`) Do (
        Set "P=%%~tf"
        Call Set "P=%ComputerName%\%%P:~6,4%%\%%P:~3,2%%\%%P:~0,2%%"
        For %%s In (%SS%) Do (Call Set "PP=%%~s\%%P%%" &Echo F|Call xcopy /D "%%f" "%%PP%%\">nul)
    )
    Popd
Pause
Exit /B 0