Сравнение содержимого двух папок и вывод на экран различия

@Greeny · Регистрация: 16.12.2015

Author24 — интернет-сервис помощи студентам

Имеются две папки (1,2) Помогите создать батник, что бы он мог сравнить две папки, а затем выводить, каких файлов нет в 1 папке по отношению ко 2, а каких наоборот.

greg zakharov · 18.12.2015, 11:17

Если предположить, что обе папки находятся в одной и той же общей папке и их именами являются dir1 и dir2, а командный сценарий запускается из этой общей папки, то:

Windows Batch file

@echo off
  setlocal enabledelayedexpansion
    echo:FileName                        Dir1   Dir2
    echo:--------                        ----   ----
    for /f "tokens=*" %%i in (
      'dir /a-d /s /b dir1'
    ) do (
      set "itm=%%~i"
      set "itm=!itm:dir1=dir2!"
      set "nwe=%%~nxi"
      call:strLen "!nwe!"
      if !len! lss 32 (
        for /l %%j in (!len!, 1, 31) do set "nwe=!nwe! "
      )
      if exist "!itm!" (
        echo:!nwe!true   true
      ) else (
        echo:!nwe!true   false
      )
    )
  endlocal
exit /b
 
:strLen
  set "s=%~1"
  set "len=1"
  for /l %%i in (1, 1, 255) do (
    set "c=!s:~%%i!"
    if defined c set /a "len+=1"
  )
exit /b

Примерный вывод:

Код

FileName                        Dir1   Dir2
--------                        ----   ----
Build.sql                       true   true
Util.sql                        true   false
...

@Greeny · 19.12.2015, 17:05 **[ТС]**

Спасибо.Очень помог)))

@Greeny 0 / 0 / 0 Регистрация: 16.12.2015 Сообщений: 2
		1
	Сравнение содержимого двух папок и вывод на экран различия 16.12.2015, 22:36. Показов 9792. Ответов 2 Метки нет (Все метки) Имеются две папки (1,2) Помогите создать батник, что бы он мог сравнить две папки, а затем выводить, каких файлов нет в 1 папке по отношению ко 2, а каких наоборот. 0

@Greeny 0 / 0 / 0 Регистрация: 16.12.2015 Сообщений: 2
	19.12.2015, 17:05 [ТС]	3
	Спасибо.Очень помог))) 0

Сравнение содержимого двух папок и вывод на экран различия

Решение