Удаление первых 6-ти строк во всех текстовых файлах, находящихся в определённой папке

@Programmer 111 · Регистрация: 15.12.2014

Author24 — интернет-сервис помощи студентам

Привет. Пытаюсь создать BAT CMD файл удаляющий первые 6 строк в каждом файле папки. В папке приблизительно 170 файлов и таких папок 182 штуки. То есть вручную это делать, мягко говоря, не вариант. Имеется вот такой код для одного файла, но он не работает

Windows Batch file

for /f "skip=6 delims=*" %%a in ("C:\Users\Ok\Desktop\Geolife Trajectories 1.3\Data\000\Trajectory\1.txt") do (
echo %%a >>C:\Users\Ok\Desktop\Geolife Trajectories 1.3\Data\000\Trajectory\2.txt    
)
xcopy C:\Users\Ok\Desktop\Geolife Trajectories 1.3\Data\000\Trajectory\2.txt C:\Users\Ok\Desktop\Geolife Trajectories 1.3\Data\000\Trajectory\1.txt /y
del C:\Users\Ok\Desktop\Geolife Trajectories 1.3\Data\000\Trajectory\2.txt /f /q

ВОПРОС 1 - Как его заставить работать хотя бы для одного файла;
ВОПРОС 2 - Как его расширить, чтобы он работал для всех файлов в папке.

@ComSpec · 29.11.2015, 19:05

Для одного файла:

Windows Batch file

@echo off
 
set "file=C:\Users\Ok\Desktop\Geolife Trajectories 1.3\Data\000\Trajectory\1.txt"
 
>.tmp more +6 "%file%"& >nul move .tmp "%file%"
 
exit/b

.

Для всех текстовых файлов в папке:

Windows Batch file

@echo off
 
set "dir=C:\Users\Ok\Desktop\Geolife Trajectories 1.3\Data\000\Trajectory"
 
for %%i in ("%dir%\*.txt") do >.tmp more +6 "%%i"& >nul move .tmp "%%i"& echo %%~nxi
 
exit/b

.

@Programmer 111 · 29.11.2015, 23:48 **[ТС]**

Спасибо, работает!

Добавлено через 3 часа 42 минуты
По ходу выполнения появился дополнительный вопрос. Попытался переделать код, чтобы работал по всем папкам в родительской папке. BAT файл доходит до определенного места (обрабатывает 9 папок) и останавливается...?

Windows Batch file

@echo off
 
set "dir=C:\Users\Ok\Desktop\Geolife Trajectories 1.3\Data"
 
for /R %%i in ("*.plt") do >.tmp more +6 "%%i"& >nul move .tmp "%%i"& echo %%~nxi
 
exit/b

@ComSpec · 30.11.2015, 00:37

Windows Batch file

@echo off
 
set "dir=C:\Users\Ok\Desktop\Geolife Trajectories 1.3\Data"
 
for /r "%dir%" %%i in ("*.plt") do >.tmp more +6 "%%i"& >nul move .tmp "%%i"& echo %%~nxi
 
exit/b

@Programmer 111 · 30.11.2015, 01:19 **[ТС]**

Спасибо, но по прежнему доходит до определенного места и перестает удалять. В родительской папке 182 папки (в каждой примерно 170 файлов), слишком большая рекурсия видимо.

Добавлено через 34 минуты
Хотя скрипт на изменение расширения проходит все файлы во все папках.

Windows Batch file

@ECHO OFF
PUSHD .
FOR /R %%d IN (.) DO (
    cd "%%d"
    IF EXIST *.plt (
       REN *.plt *.txt
    )
)
POPD

@alpap · 30.11.2015, 16:09

Попробуйте так изменить:

Windows Batch file

@echo off
 
set "dir=C:\Users\Ok\Desktop\Geolife Trajectories 1.3\Data"
 
for /f "delims=" %%i in ('dir /a-d /b /s "%dir%\*.plt"') do >.tmp more +6 "%%i"& >nul move .tmp "%%i"& echo %%~nxi
 
exit/b

.

@Programmer 111 · 30.11.2015, 23:09 **[ТС]**

Спасибо, но все равно такая же ситуация. В общем написал скрипт, который копирует этот файл во все подкаталоги, сейчас пытаюсь написать скрипт который вызовет все эти BAT файлы, но что-то не хочет работать

Windows Batch file

@echo off
 
set "dir=C:\Users\Ok\Desktop\Geolife Trajectories 1.3\Data"
 
for /r "%dir%" %%i in ("*.bat") do CALL (BAT4.bat)
 
exit/b

Добавлено через 2 часа 53 минуты
Спасибо большое. Задача решена. Проблема была в конкретном файле, при его удалении скрипты сработали.

Удаление первых 6-ти строк во всех текстовых файлах, находящихся в определённой папке

Решение

Решение

Решение

	30.11.2015, 23:09