Расчёт дат для их использования в именах файлов и папок при переименовании

@echo off
SetLocal EnableExtensions
 
::Задайте папку, в которой переименовуем файл (по умолчанию . - текущая)
set Folder=.
 
::Задайте имя файла excel (без расширения)
set xlName=График 2016
 
call :ParseDateSafe "%Date%" DayToday MonthToday YearToday
 
set /a MonthToday+=1
if %MonthToday%==13 (set MonthToday=1& set /a YearToday+=1)
 
For /f "tokens=%MonthToday%" %%a in ("Январь Февраль Март Апрель Май Июнь Июль Август Сентябрь Октябрь Ноябрь Декабрь") do set NextMonthName=%%a
 
:: удаляем последнее слово из имени
set "xlNameNew=%xlName: =.%" 
for /f %%a in ("%xlNameNew%") do set "xlNameNew=%%~na"
set "xlNameNew=%xlNameNew:.= %"
 
:: Переименовываем
ren "%Folder%\%xlName%.xls*" "%xlNameNew% %NextMonthName% %YearToday%.*"
 
pause
goto :eof
 
:ParseDateSafe [Дата] [Переменная - День] [Переменная - Месяц] [Переменная - Год]
  :: Функция безопасного парсинга даты на составляющие вне зависимости от настроек региональных стандартов
  if not Defined iDate For /F "Tokens=1,3" %%i IN ('REG QUERY "HKCU\Control Panel\International" /s^|FindStr /C:"iDate" /C:"sDate"') DO Set "%%i=%%j"
  set "DateToParse=%~1"
  For /F "Tokens=2" %%? IN ("%~1") Do if not "%%?"=="" set "DateToParse=%%?"
  For /F "Tokens=1-4* Delims=%sDate% " %%A IN ("%DateToParse%") Do (
    If "%iDate%"=="0" Set "Year=%%C"& Set "Month=%%A"& Set "Day=%%B"
    If "%iDate%"=="1" Set "Year=%%C"& Set "Month=%%B"& Set "Day=%%A"
    If "%iDate%"=="2" Set "Year=%%A"& Set "Month=%%B"& Set "Day=%%C"
  )
  if "%Month:~,1%"=="0" set Month=%Month:~-1%
  if "%Day:~,1%"=="0" set Day=%Day:~-1%
  set "%~2=%Day%"& set "%~3=%Month%"& set "%~4=%Year%"
Exit /B

::Новая папка
set FolderNew=c:\temp

copy "%Folder%\%xlName%.xls*" "%FolderNew%\*.*"
ren "%FolderNew%\%xlName%.xls*" "%xlNameNew% %NextMonthName% %YearToday%.*"

cd /d "%~dp0"