Замена в файле нужного байта. Ассемблер, tasm

@123rustem45 · Регистрация: 24.02.2013

Author24 — интернет-сервис помощи студентам

Как поменять в файле 10 байт? Программа выводит 10 байт, но не заменяет его

Assembler

.model small
org 100h                
.data
fname db 'hello.txt',0
buffer    db 2      
handle    dw ?      
.code
start:
    mov ax, @data
    mov ds, ax
    mov ah,3Dh             
    xor al,al     
    lea dx,fname  
    xor cx,cx       
int 21h   
mov [handle],ax   
mov AH, 42h
mov BX, handle
mov AL, 00 
mov CX, 00
mov DX, 10
    xor al,al 
    lea dx,fname    
repne scasb
    mov byte ptr[bx],'5'
int 21h
  mov ah,3Fh        
    lea dx,buffer      
    mov cx,1       
    int 21h             
lea bx,buffer
    add bx,ax           
    mov byte ptr [bx],'$'    
    mov ah,9
    lea dx,buffer
    int 21h        
close_file:
    mov ah,3Eh      
    mov bx,[handle]   
    int 21h           
exit:
    mov ah,0        
    int 16h        
    mov ax,4C00h        
    int 21h    
end start

@Black Fregat · 10.04.2014, 13:50

Во превых, код у Вас неправильный.
Строки 22-25 явно не к месту.
Они затрут информацию для int 21h.

Во вторых, чтобы записать в файл, нужно:
1) При открытии файла через int 21h AH=3Dh (Open) установить режим "чтение/запись": AL=2
2) Повторно выполнить int 21h AH=42h (Seek) и подвести указатель к нужному месту
3) Собственно выполнить запись через int 21h AH=40h (Write)

@123rustem45 · 10.04.2014, 19:24 **[ТС]**

Сообщение от Black Fregat

Повторно выполнить int 21h AH=42h (Seek) и подвести указатель к нужному месту

Как это сделать?)

Assembler

.model small
org 100h                
.data
fname db 'hello.txt',0
endline   db 13,10,'$'
buffer    db 2   
handle    dw ?      
.code
start:
    mov ax, @data
    mov ds, ax
    mov ah,3Dh 
    mov Al, 02        
    xor al,al     
    lea dx,fname  
    xor cx,cx       
int 21h   
mov [handle],ax   
    mov AH, 42h
    mov BX, handle
    mov AL, 00 
    mov CX, 00
    mov DX, 9 ; 10-й байт 
    int 21h
mov AH, 42h 
mov BX, handle
mov AL, 00 
mov CX, 00
mov DX, 0 ; на 1-й байт 
int 21h
    mov AH, 40h 
    mov BX, handle
    mov CX, 2 
    lea DX, handle
    int 21h   
mov ah,3Fh        
    lea dx,buffer      
    mov cx,20      
    int 21h  
lea bx,buffer
    add bx,ax           
    mov byte ptr [bx],'$'    
    mov ah,9
    lea dx,buffer
    int 21h     
close_file:
    mov ah,3Eh      
    mov bx,[handle]   
    int 21h           
exit:
    mov ah,0        
    int 16h        
    mov ax,4C00h        
    int 21h    
end start

@Black Fregat · 10.04.2014, 23:24

Вам ведь нужно один и тот же байт сначала считать, потом записать?
Значит, нужно подвести указатель к нужному байту и прочитать.
При чтении указатель сдвинется, его нужно вернуть на то же место и записать.

Последовательность действий должна быть такой:
1) int 21h AH=3Dh (Open)
2) int 21h AH=42h (Seek)
3) int 21h AH=3Fh (Read)
4) int 21h AH=42h (Seek)
5) int 21h AH=40h (Write)
6) int 21h AH=3Eh (Close)

Добавлено через 22 минуты
В общем, примерно так

код здесь

Assembler

.model small
.data
fname db 'hello.txt',0
endline   db 13,10,'$'
newbyte   db 'Z'
buffer    db 2 dup (?)   
handle    dw ?      
.stack
.code
start:
    mov ax, @data
    mov ds, ax
    mov AX, 3D02h 
    lea dx, fname  
    xor cx, cx       
    int 21h   
    mov handle, ax   
    
    mov AH, 42h
    mov BX, handle
    mov AL, 00 
    mov CX, 00
    mov DX, 9 ; 10-й байт 
    int 21h
    
    mov ah, 3Fh        
    lea dx, buffer      
    mov cx, 1      
    int 21h  
    
    lea bx, buffer
    add bx, ax           
    mov byte ptr [bx], '$'    
    mov ah, 9
    lea dx, buffer
    int 21h
 
    mov AH, 42h
    mov BX, handle
    mov AL, 00 
    mov CX, 00
    mov DX, 9 ; 10-й байт 
    int 21h
         
    mov AH, 40h 
    mov BX, handle
    mov CX, 1
    push DS
    pop ES 
    lea DX, newbyte
    int 21h 
      
close_file:
    mov ah,3Eh      
    mov BX, handle
    int 21h           
    
exit:
    mov ah, 0        
    int 16h        
    mov ax, 4C00h        
    int 21h    
end start

@Black Fregat Фрилансер 3709 / 2082 / 567 Регистрация: 31.05.2009 Сообщений: 6,683
	10.04.2014, 13:50	2
	Во превых, код у Вас неправильный. Строки 22-25 явно не к месту. Они затрут информацию для int 21h. Во вторых, чтобы записать в файл, нужно: 1) При открытии файла через int 21h AH=3Dh (Open) установить режим "чтение/запись": AL=2 2) Повторно выполнить int 21h AH=42h (Seek) и подвести указатель к нужному месту 3) Собственно выполнить запись через int 21h AH=40h (Write) 2

	10.04.2014, 23:24

Замена в файле нужного байта. Ассемблер, tasm

Решение