Нарисовать 4 квадрата по углам экрана

;Тестирование ВК
Stck Segment Stack
     db 512 dup(?)
Stck EndS
 
Data Segment
     mem_adr dw 0A000h
     color   db ?
     msk     db ?
Data EndS
 
Code Segment Public 'Code'
     Assume CS:Code,DS:Data
 
START PROC FAR
     Mov   AX,Data
     Mov   DS,AX
 
     Mov   AX,12h            ;инициализация  режима дисплея 640х480х16
     Int 10h
 
     Mov   AX,Mem_Adr
     Mov   ES,AX
 
     Mov   DX,3CEh                ;выбор порта  управления
     Mov   AL,5                   ;выбор 5-го  рeгистра   ВК
     out   DX,AL
     Inc   DX                     ; адрес порта  данных
     Mov   AL,0                   ;режим записи 0
     out   DX,AL
     mov bx,0d                    ;вывод 8 пикселей  красного цвета
     mov cx,64d; счетчик строк
 
label1:
      mov al,04d    
      call dop  
      mov al,00d
      call dop  
      mov al,00d
      call dop  
      mov al,00d
      call dop  
      mov al,00d
      call dop
      mov al,00d
      call dop      
      mov al,00d
      call dop
      mov al,15d
      call dop  
      loop label1
 
     Mov   AH,0
     Int 16h                            ; Press any key...
     Mov  AX,0003h
     Int 10h                             ; Text Mode
     Mov  AH,4Ch
     Int 21h
START EndP
 
dop proc
    push dx
    push cx
    mov cx,10d
label2: add bx,1d
    Mov   msk,11111111b
        Mov   color,al             
        CALL FILLRECT            
        dec cx               
        cmp cx,0         
        jne label2
    pop dx
    pop cx
dop endp
 
FILLRECT PROC
      push ax
      push dx
     Mov  DX,3CEh
     Mov  AL,8                   ; 8-ой регистр ВК
     out  DX,AL
 
     Inc  DX
     Mov  AL,msk
     out  DX,AL
 
      Mov  AL,ES:[BX]            ; читаем содержимое защелки
     Mov  AL,0
     Mov  ES:[BX],AL             ; очищаем защелку
 
     Mov  DX,3C4h
     Mov  AL,2                   ; 2-ой регистр секвенсора
     out  DX,AL
 
     Inc  DX                     ;  адрес порта  данных секвенсора
     Mov  AL,color
     out  DX,AL
     Mov  AL,0FFh
     Mov  ES:[BX],AL             ; прорисовка  пикселя
      pop dx
      pop ax
     ret
FILLRECT EndP
 
Code EndS
     End START

; Подпрограмма plot на основе книги
; Р Уилтон "Видеосистемы персональных компьютеров IBM PC и PS/2
; руководство по программированию"
 
    .model small
    .code
RED=8+4
GREEN=8+2
BLUE=8+1
WHITE=15
 
; вывод точки (VGA 640*480*16 цветов)
; x=cx, y=dx, color=al
 
color   db 0
 
plot:   push di
    push es
    push cx
    push dx
    mov al,color
    cmp cx,640 ; координаты выходят за границы экрана ?
    jnc pl1
    cmp dx,480
    jnc pl1
    push ax ; ---
    mov ax,80 ; di=80*y+(x/8)
    mul dx
    push cx
    rept 3
    shr cx,1
    endm
    add ax,cx
    mov di,ax
    pop cx
    and cl,7
    xor cl,7 ; CL= # of bits to shift left
 
; отрисовка в видео память
    mov ax,0A000h
    mov es,ax
 
; set Graphics Controller write mode 2
    mov dx,3CEh     ; GC address register port
    mov ah,1        ; AH= unshifted bit mask
    shl ah,cl       ; AH= bit mask in proper pos.
    mov al,8        ; AL= Bit register #
    out dx,ax
    mov ax,205h     ; AL= Mode register number
    out dx,ax       ; AH= Write Mode 2(bits 0,1)
                ;     Read Mode 0 (bit 3)
    mov ax,0003     ; AL= Function Select reg. # (code 0 - dot replace)
;   mov ah,3*8              ; (3*8 - dot XOR - code 3)
;   mov al,3
    out dx,ax       ; AH= read-modify-write bits
 
    pop ax ; ---
; чтение (в "защелки" VGA) затем запись
    xchg    al,es:[di]  ; выводим точку
 
; restore default Graphics Controller register value
    mov ax,0FF08h   ; default Bit Mask
    out dx,ax
    mov ax,0005     ; default Mode register
    out dx,ax
    mov ax,0003     ; default Function Select
    out dx,ax
 
pl1:    pop dx
    pop cx
    pop es
    pop di
    ret
 
sq: mov color,al ; квадрат 64*64 точки цвета al c координатами cx, dx
    mov al,64
sq1:    mov ah,64
    push dx
    push cx
sq2:    push ax
    call plot
    pop  ax
    inc cx
    dec ah
    cmp ah,0
    jnz sq2
    pop cx
    pop dx
    inc dx
    dec al
    cmp al,0
    jnz sq1
    ret
 
start:  push cs
    pop  ds
    mov ax,12h ; видео режим 640*480*16 цветов
    int 10h
; рисуем 4 квадрата
; красный, синий, зеленый, белый
    mov cx,0
    mov dx,0
    mov al,RED
    call sq
    mov cx,640-64
    mov dx,0
    mov al,BLUE
    call sq
 
    mov cx,0
    mov dx,480-64
    mov al,GREEN
    call sq
    mov cx,640-64
    mov dx,480-64
    mov al,WHITE
    call sq
; ожидание нажатия на клавишу
    mov ah,0
    int 16h
; текстовый режим
    mov ax,3
    int 10h
; выход в Дос
    mov ax,4C00h
    int 21h
 
    end start