Если символ, на который указывает курсор мыши, является шестнадцатеричной цифрой, то увеличить ее на 1

    .model small
    .code
mousex  dw 0
mousey  dw 0
scradr  dw 0
digits  db "0123456789ABCDEF"
emess   db "Mouse driver not present",13,10,"$"
table   db "Press mouse buttons on digits",13,10,13,10
        db "+---+---+---+---+",13,10
        db "| 1   2   3   4 |",13,10
        db "| 5   6   7   8 |",13,10
        db "| 9   A   B   C |",13,10
        db "| D   E   F   0 |",13,10
        db "+---+---+---+---+",13,10,"$"
 
getsymb:push es     ; прочитать символ al с дисплея
    mov di,0B800h
    mov es,di   ; es=видео сегмент
    mov ax,mousey
    mov di,80
    mul di
    add ax,mousex
    mov di,ax   ; di=80*mousey+mousex
    add di,di   ; di=di*2
    mov scradr,di   ; сохранить адрес символа
    mov al,es:[di]  ; прочитать символ
    pop es
    ret
 
putsymb:push es     ; записать символ al на ту же позицию
    mov di,0B800h
    mov es,di   ; es=видео сегмент
    mov di,scradr
    mov es:[di],al  ; записать символ
    pop es
    ret
 
; Это 16ричная цифра ?
; Если да, то cl=число, соответствующее цифре
isdigit:mov di,offset digits ; найти al в строке
    mov cx,10h ; длина строки = 16 символов
    repne scasb
    jne id1    ; переход, если не найден
    xor cx,0Fh ; cl=позиция в строке (значение цифры)
    clc
    ret
id1:    stc
    ret
 
; макро - функции мышки
mouse   macro num
    mov ax,num
    int 33h
    endm
 
; подпрограмма операций мыщкой
change: cmp bx,0
    jnz  cha1
    ret ; если клавиши не нажаты, то возврат
cha1:   mouse 2 ; скрыть курсор мышки
    cmp bx,1 ; нажата ЛКМ - увеличение цифры
    jz changinc
    cmp bx,2 ; нажата ПКМ - уменьшение цифры
    jz  changedec
    jmp mouseon ; иначе переход к концу подпрограммы
 
changinc:
    call getsymb ; считать символ в позиции мышки
    call isdigit ; это цифра ?
    jc  mouseon  ; нет
    cmp cl,15    ; да, это 0Fh ?
    jz mouseon   ; если да, то не трогать
    INC cl       ; увеличение числа на 1
    mov al,cl    ; преобразование al в цифру
    mov bx,offset digits
    xlat
    call putsymb ; запись al в видео память
    jmp mouseon  ; переход к концу подпрограммы
 
changedec:       ; аналогично, только с операцией DEC cl
    call getsymb
    call isdigit
    jc mouseon
    cmp cl,0     ; это 0 ?
    jz  mouseon  ; если да, то не трогать
    DEC cl       ; уменьшение числа на 1
    mov al,cl
    mov bx,offset digits
    xlat
    call putsymb
    jmp mouseon
 
; окончание подпрограммы
mouseon:mouse 1    ; включить курсор мышки
on1:    mouse 3    ; ожидать отпускание клавищ мышки
    cmp bx,0
    jnz on1
    ret
 
; ошибка - нет драйвера мышки
mouseerr:mov dx,offset emess
    mov ah,9
    int 21h
    mov ax,4C01h
    int 21h
 
; основная программа
start:  mov ax,cs
    mov ds,ax
    mov es,ax
    mouse 0   ; инит мышку
    cmp ax,-1 ; если драйвера нет, то выход с ошибкой
    jnz mouseerr
        mov bx,0  ; задать цвет софт курсора мышки
    mov cx,00FFh
    mov dx,4E00h
    mouse 0Ah
    mov dx,offset table ; вывести тестовый текст
    mov ah,9
    int 21h
    mouse 1  ; включить курсор
m0: mov ah,1 ; клавиша на клавиатуре нажата ?
    int 16h
    jnz ex   ; да, завершение программы
    mouse 3  ; опрашивать мышку
; преобразовать cx,dx в позицию текста (cx=cx/8, dx=dx/8)
    rept 3
    shr cx,1
    shr dx,1
    endm
    mov mousex,cx
        mov mousey,dx
    call change ; обработать действие мышки
    jmp m0
ex: mov ah,0    ; выход, поглотить код нажатой клавиши
    int 16h
    mouse 2     ; скрыть курсор мышки
    mov ax,4C00h ; выход в Дос
    int 21h
    end start