Вывести из массива 4х5 только последний столбец

.model  tiny
.286
code    segment
org 100h
 
start:
 
;Пользовательский ввод массива из 20 символов
 
    mov ah, 0Ah
    mov dx, offset array
    int 21h
 
;Установка смещения на последнее число первой строки матрицы
;и копирование его в индексный регистр для обращения к памяти.
 
    add dx, 5d
    mov si, dx
 
;Установка количества строк в матрице
;и смещения области памяти для записи в неё последнего столбца матрицы.
 
    mov cl, 5d
    mov di, offset outstr   
 
;Запись последнего столбца матрицы в отдельный массив
 
write:
 
    mov al, byte ptr[si]
    mov byte ptr[di+1], al
    add si, 4d
    inc di
    loop write          
 
;Вывод на экран
    
    mov ah, 9d
    mov dx, offset outstr
    int 21h
 
;Завершение программы
 
    mov ax, 4C00h
    int 21h
 
array       db  21d, 22d dup(0)
outstr      db  0Ah, 6d dup(24h)
 
code    ends
end start

.model  tiny
.286
code    segment
org     100h
 
 
start:
 
;Запись смещения массива в индексный регистр
;для последующей работы с этой областью памяти.
 
    mov di, offset matrix
 
;Пользователь вводит 20 чисел с клавиатуры
;в десятичной системе счисления.
 
    mov cx, 20d
 
usrin:
 
    push di
    call invar  
    add di, 2d
    loop usrin
 
;Перенос строки.
 
    mov ah, 2d
    mov dl, 0Ah
    int 21h
 
;Установка смещения в индексном регистре на последнее число
;первой строки матрицы.
 
    mov di, offset matrix
    add di, 6d  
 
;Вывод сообщения для пользователя.
 
    mov ah, 9d
    mov dx, offset mes
    int 21h
    
;Вывод последнего столбца матрицы на экран.
 
    mov cx, 5d
    mov dx, offset return
    
outdisp:
 
    
    push word ptr[di]
    call outvar
    int 21h
    add di, 8d
    loop outdisp
 
    mov ax, 4C00h
    int 21h
 
matrix      dw  4d dup(0)
        dw  4d dup(0)
                dw  4d dup(0)
        dw  4d dup(0)
        dw  4d dup(0)
 
return      db  0Ah, 0Dh, 24h
mes     db  'Последний столбец матрицы:', 0Ah, 0Dh, 24h
 
;Процедура ввода числа в переменную.
;Параметры (передача через стек):
;- смещение переменной
;Выход:
;- Число, записанное в переменную.
 
invar   proc    uses ax bx dx cx bp si di
 
    mov bp, sp
    xor cx, cx
 
;Копирование смещения переменной в индексный регистр
;для последующей работы с этой областью памяти.
 
    mov di, word ptr ss:[bp+16] 
 
;Пользовательский ввод числа до 65535d
 
    mov ah, 0Ah
    mov dx, offset buff
    int 21h
 
;Установка смещения на последний символ массива
;и установка значения регистра-счётчика
;для определения кол-ва чисел в массиве.
    
    mov si, dx
    mov cl, byte ptr[si+1]
    add si, cx
    inc si  
    
;Установка значения множителя разряда  
 
    mov bx, 1d
        
;Преобразование кодов ASCII в число
            
translate:
        
    xor ax, ax
    mov al, byte ptr[si]
    sub al, 30h
    mul bx  
    add word ptr[di], ax
    mov ax, factor
    mul bx
    mov bx, ax
    dec si
    loop translate
    
    ret 2
 
buff    db  6d, 7d dup(0)   
factor  equ 10d
 
invar   endp
 
;Процедура вывода на экран значения переменной.
;Входные параметры(передача через стек):
;- число (не более 65535)
;Выход:
;- число в десятичной системе счисления на экране
 
 
outvar      proc    uses ax bx dx bp di cx
 
    mov bp, sp
    xor dx, dx
 
;Установка делителя в регистр BX.  
 
    mov bx, 10d
 
;Запись смещения последнего числа массива
;в индексный регистр для последующей
;работы с этой областью памяти.
 
    mov di, offset outmas+4
 
;Запись смещения массива для последующей
;работы с ним.    
 
    mov si, offset outmas
    
;Запись преобразуемого числа в регистр АХ.
    
    mov ax, word ptr ss:[bp+14]
    cmp ax, 0
    je zero
    
;Преобразование числа в коды ASCII.
    
trans:
        
    cmp ax, 0
    je delzero      
    
    div bx
    add dl, 30h
    mov byte ptr[di], dl
    xor dx, dx
    dec di
    jmp trans   
 
;Удаление нулей в начале массива(если они есть).
 
 
delzero:
        
    cmp byte ptr[si], 0
    je delz
    jmp exitp
        
delz:
     
    inc di
    cmp byte ptr[di], 24h
    je exitp
    mov al, byte ptr[di]
    mov byte ptr[di], 24h
    mov byte ptr[si], al
    inc si
    jmp delzero
 
zero:
 
    mov byte ptr[di-4], 30h
 
exitp:
    
    mov ah, 9d
    mov dx, offset outmas
    int 21h
 
    mov cx, 5d
    mov di, dx
 
;Очистка массива после использования.
 
masz:
    
    mov byte ptr[di], 0
    inc di
    loop masz       
 
    ret 2
 
outmas  db  5d dup(0), 24h
 
outvar      endp
 
code    ends
end     start