Дан массив из 11 байт. Посчитать количество байт, в которых нет единиц, стоящих рядом

.model small
 
.stack 200h
 
.data
        CrLf            db      0Dh, 0Ah, '$'
        msgResult       db      'Result: ', '$'
        msgPressAnyKey  db      0Dh, 0Ah, 'Press any key to exit...', '$'
        N               dw      11
        Array           db      67, 30, 94, 76, 47, 40, 56, 22, 28, 55, 127
.data?
        Result          dw      ?
.code
 
main    proc
        ;инициализация сегментного регистра ds адресом сегмента данных
        mov     ax,     @data
        mov     ds,     ax
 
        ;обработка массива
        lea     si,     [Array]
        mov     cx,     [N]
        mov     dx,     0       ;количество элементов массива, удовлетворяющих условию
        forI:
                lodsb
                push    cx
                mov     ah,     11b
                mov     cx,     6
                forJ:
                        mov     bl,     al
                        and     bl,     ah
                        cmp     bl,     ah
                        je      @@NoGood
                        shl     ah,     1
                loop    forJ
                inc     dx
        @@NoGood:
                pop     cx
        loop    forI
        mov     [Result],       dx
 
        ;вывод результата
        mov     ah,     09h
        lea     dx,     [msgResult]
        int     21h
        mov     ax,     [Result]
        mov     bx,     10              ;делитель (основание системы счисления)
        mov     cx,     0               ;количество выводимых цифр
        @@div:
                xor     dx,     dx      ;делим (dx:ax) на bx
                div     bx
                add     dl,     '0'     ;преобразуем остаток деления в символ цифры
                push    dx              ;и сохраняем его в стеке
                inc     cx              ;увеличиваем счётчик цифр
                test    ax,     ax      ;в числе ещё есть цифры?
        jnz     @@div                   ;да - повторить цикл выделения цифры
        @@show:
                mov     ah,     02h     ;функция ah=02h int 21h - вывести символ из dl на экран
                pop     dx              ;извлекаем из стека очередную цифру
                int     21h             ;и выводим её на экран
        loop    @@show                  ;и так поступаем столько раз, сколько нашли цифр в числе (cx)        pop     bx
 
        ;ожидание нажатия любой клавиши
        mov     ah,     09h
        lea     dx,     [msgPressAnyKey]
        int     21h
 
        mov     ah,     00h
        int     16h
 
        ;завершение программы
        mov     ax,     4C00h
        int     21h
main    endp
 
end     main