Возникает ошибка "Деление на ноль", когда на ноль ничего и нигде не делится

@keldranace · Регистрация: 14.05.2019

Author24 — интернет-сервис помощи студентам

Написал программу, которая выводит на экран координаты клика мыши.

Assembler

SSEG    segment stack       
        db 256 dup(0)
SSEG    ends
 
DSEG    segment         
        mess   db 'Privet',0dh,0ah,'$'
        mess2  db 'Privet and ty for click!!!',0dh,0ah,'$'
        x_coord dw ?
        y_coord dw ?
        snake dw ?
        
DSEG    ends
 
CSEG    segment         
        assume cs:CSEG,ds:DSEG,ss:SSEG
begin:
        mov ax,DSEG 
        mov ds,ax       
                      
        mov ah,09h                       
        mov dx,offset mess      ;privet
 
        mov ax,13h
        int 10h
        
        
        
        ;int 21h    
        
        mov ax,00h              ;initialyze mouse
        int 33h
        mov ax,01h              ;show kursor
        int 33h
        
        mov ax,cs               ;mov adr of cs
        mov es,ax               ;to ex, for offset handler
        mov ax,000ch            ;set handler
        mov cx,0002h            ;event - lcm
        mov dx,offset click_handler
        int 33h 
        
        
        mov ah,01h              ;WAIT
        int 21h 
        
        mov ax,000ch            ;delete handler
        mov cx,0000h            ;event -  none
        int 33h
        
        mov ah,01h              ;WAIT
                int 21h                              
                mov ah,4ch              ;prog ENDS
                int 21h 
                         
click_handler:
        mov ax,DSEG             ;for exe
                mov ds,ax               ;for exe
        
        ;push dx                    !!!!!!!!
        ;mov dl,02h               !!!!!!!!
        ;xor ax,ax                  !!!!!!!!
        ;mov ax,cx                 !!!!!!!!
        ;div dl                        !!!!!!!!
        ;mov cx,ax                 !!!!!!!!
        ;pop dx                      !!!!!!!!
        
        
        mov x_coord,cx
        mov y_coord,dx
        
        mov ax,x_coord
        call far ptr print_num
        mov ax,y_coord
        call far ptr print_num
        
 
        retf
        
print_num proc far
        mov si,10
        mov ax,ax               ;FIRST LOAD IN AX
        mov cx,0
a:      
        mov dx,0
        div si
        add dx,'0'
        push dx
        inc cx
        cmp ax,0
        jnz a
aa: 
        pop dx
        mov ah,02h
        int 21h
        loop aa
        mov dl,0ah
        int 21h
 
        retf
print_num endp      
        
CSEG    ends        
end begin

Если убрать кусок кода, выделенный комментарием и восклицательными знаками, то программа работает полукорректно: Выводит удвоенную координату x и верную координату y.
При добавлении куска кода программа начинает работать очень странно: теперь в левой части экрана координата x выводится верно, но только до значения 255. Если кликнуть на часть экрана, которая находится правее программа "ломается". В отладчике при клике в этой области выдает ошибку: divided by zero.
Помогите пожалуйста найти проблему

@Ethereal · 09.06.2019, 11:40

Сообщение от keldranace

При добавлении куска кода программа начинает работать очень странно: теперь в левой части экрана координата x выводится верно, но только до значения 255.

И это естественно. Команда div генерирует прерывание от деления на 0 не только при делении на 0, но и еще если частное не влезает в тот регистр куда должно помещаться. Ты у себя в коде использовал такое div , что частное - байт. Максимальное значение байта 255. Максимальное значение байта 255. Как только результат деления координаты на 2 становился больше 255 команда div генерировала прерывание по делению на 0, поскольку частное не влезало в байт.

Добавлено через 2 минуты

Сообщение от keldranace

div dl !!!!!!!! ;
mov cx,ax !!!!!!!!

Ты кстати командой div dl получаешь в al частное, а в ah остаток. А потом конкатенацию всего этого засовываешь в cx якобы это координата деленная пополам. А это частное к которому приставлен остаток.

Добавлено через 53 секунды
Тупо почитай что на что делит div и куда сует результаты в двух случаях - когда делитель байт и когда делитель слово. Тебе надо было использовать вариант когда делитель - слово. Тогда и частное - слово и любая координата на экране в него влезет.

Добавлено через 1 минуту
А вообще весь тобой закомментированный кусочек заменяется на одну команду
shr cx,1
и никакого тебе деления на ноль. Потому-что сдвиг беззнакового на бит вправо это и есть деление на два.

@keldranace · 09.06.2019, 11:57 **[ТС]**

Спасибо тебе огромное.
Ведь и все вроде знаю, и команду shr, и то, как div ведет себя в зависимости от размера делителя, но когда дело доходит до практики то все забывается.
Не знаю, что бы делал без тебя

@Ethereal 6770 / 2739 / 384 Регистрация: 17.02.2013 Сообщений: 4,048
	09.06.2019, 11:40	2
	Сообщение было отмечено keldranace как решение Решение Сообщение от keldranace При добавлении куска кода программа начинает работать очень странно: теперь в левой части экрана координата x выводится верно, но только до значения 255. И это естественно. Команда div генерирует прерывание от деления на 0 не только при делении на 0, но и еще если частное не влезает в тот регистр куда должно помещаться. Ты у себя в коде использовал такое div , что частное - байт. Максимальное значение байта 255. Максимальное значение байта 255. Как только результат деления координаты на 2 становился больше 255 команда div генерировала прерывание по делению на 0, поскольку частное не влезало в байт. Добавлено через 2 минуты Сообщение от keldranace div dl !!!!!!!! ; mov cx,ax !!!!!!!! Ты кстати командой div dl получаешь в al частное, а в ah остаток. А потом конкатенацию всего этого засовываешь в cx якобы это координата деленная пополам. А это частное к которому приставлен остаток. Добавлено через 53 секунды Тупо почитай что на что делит div и куда сует результаты в двух случаях - когда делитель байт и когда делитель слово. Тебе надо было использовать вариант когда делитель - слово. Тогда и частное - слово и любая координата на экране в него влезет. Добавлено через 1 минуту А вообще весь тобой закомментированный кусочек заменяется на одну команду shr cx,1 и никакого тебе деления на ноль. Потому-что сдвиг беззнакового на бит вправо это и есть деление на два. 4

@keldranace 0 / 0 / 0 Регистрация: 14.05.2019 Сообщений: 22
	09.06.2019, 11:57 [ТС]	3
	Спасибо тебе огромное. Ведь и все вроде знаю, и команду shr, и то, как div ведет себя в зависимости от размера делителя, но когда дело доходит до практики то все забывается. Не знаю, что бы делал без тебя 0

Возникает ошибка "Деление на ноль", когда на ноль ничего и нигде не делится

Решение