Удаление символов из массива

format  MZ                      ;Исполняемый файл DOS EXE (MZ EXE)
entry   code_seg:start          ;Точка входа в программу
;--------------------------------------------------------------------
stack   200h                    ;Размер стека
;--------------------------------------------------------------------
segment data_seg                ;Cегмент данных
        CrLf            db      0Dh, 0Ah, '$'   ;перевод строки
        msgPressAnyKey  db      0Dh, 0Ah, 'Press any key to exit...', '$'
        msgOriginal     db      0Dh, 0Ah, 'Original array: ', 0Dh, 0Ah, '$'
        msgResult       db      0Dh, 0Ah, 'Result:', 0Dh, 0Ah
                        db      ' - length: ', '$'
        msgResult2      db      0Dh, 0Ah, ' - array:  ', '$'
        N               dw      10
        Array           dw      2, 73, 26, 7, 117, 18, 59, 121, 47, 68
        PrimesCount     dw      ?
;--------------------------------------------------------------------
;--------------------------------------------------------------------
segment code_seg                ;Сегмент кода
start:                                  ;Точка входа в программу
        mov     ax,     data_seg        ;Инициализация регистра DS
        mov     ds,     ax
 
        ;вывод исходного массива
        mov     ah,     09h
        mov     dx,     msgOriginal
        int     21h
        mov     cx,     [N]
        lea     si,     [Array]
        call    ShowArray
 
        ;обработка массива
        ; - подготовка к выполнению строчных команд
        push    es
        mov     ax,     ds
        mov     es,     ax
 
        mov     cx,     [N]
        lea     si,     [Array]
        cld
        mov     bx,     cx
        .for:
                lodsw
                test    ax,     1
                jz      .next
                        mov     di,     si
                        sub     di,     2
                        push    cx
                        push    si
                        dec     cx
                        rep     movsw
                        pop     si
                        pop     cx
                        dec     [N]
                        sub     si,     2
        .next:
 
        loop    .for
 
        pop     es
        ;вывод результата
        mov     ah,     09h
        mov     dx,     msgResult
        int     21h
        mov     ax,     [N]
        call    ShowUInt16
        mov     ah,     09h
        mov     dx,     msgResult2
        int     21h
        mov     cx,     [N]
        lea     si,     [Array]
        call    ShowArray
        ;ожидание нажатия любой клавиши
        mov     ah,     09h
        mov     dx,     msgPressAnyKey
        int     21h
        mov     ah,     0
        int     16h
 
        mov     ax,     4C00h
        int     21h                     ;Завершение программы
 
ShowUInt16:
        push    ax
        push    bx
        push    cx
        push    dx
 
        mov     bx,     10
        xor     cx,     cx
        .while:
                xor     dx,     dx
                div     bx
                add     dl,     '0'
                push    dx
                inc     cx
                or      ax,     ax
        jnz     .while
 
        mov     ah,     02h
        .for:
                pop     dx
                int     21h
        loop    .for
 
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        ret
 
ShowArray:
        pushf
        cld
        .for:
                lodsw
                call    ShowUInt16
                mov     ah,     02h
                mov     dl,     ' '
                int     21h
        loop    .for
 
        mov     ah,     09h
        lea     dx,     [CrLf]
        int     21h
        popf
        ret