Обработка целочисленного массива: заполнение по формуле, вычисление суммы, изменение элементов по правилу.

LOCALS
 
.model small
 
.stack 100h
 
.data
 
        ; массив
        N               equ     10              ; длина массива
        Array           dw      N dup (0)       ; массив
        ; параметры арифметической прогрессии для заполения массива
        a0              equ     18
        d               equ     43
        ; сумма элементов массива
        Sum             dw      0
 
        ; сообщения
        msgArray        db      'Array: ', '$'
        msgDelimiter    db      ' ', '$'
        msgSum          db      'Summa: ', '$'
        msgCrLf         db      0Dh, 0Ah, '$'
 
.code
 
;заполняет массив Array числами арифметической прогрессии
;Array[i]:=a0+d*i
FillArray       proc
        push    ax
        push    cx
        push    si
 
        mov     cx,     N
        lea     si,     Array
        mov     ax,     a0
@@For:
        mov     [si],   ax
        add     ax,     d
        add     si,     2
        loop    @@For
 
        pop     si
        pop     cx
        pop     ax
        ret
FillArray       endp
 
;выводит содержимое массива Array на экран
ShowArray       proc
        push    ax
        push    cx
        push    dx
        push    si
 
        mov     ah,     09h
        lea     dx,     msgArray
        int     21h
 
        mov     cx,     N
        lea     si,     Array
@@For:
        mov     ax,     word ptr [si]
        call    Show_AX
 
        mov     ah,     09h
        lea     dx,     msgDelimiter
        int     21h
 
        add     si,     2
        loop    @@For
 
        mov     ah,     09h
        lea     dx,     msgCrLf
        int     21h
 
        pop     si
        pop     dx
        pop     cx
        pop     ax
        ret
ShowArray       endp
 
;вычисляет сумму массива Array
;выход
; ax - сумма элементов массива
SumArray        proc
        push    cx
        push    si
 
        mov     cx,     N
        lea     si,     Array
        mov     ax,     0
@@For:
        add     ax,     word ptr [si]
        add     si,     2
        loop    @@For
 
        pop     si
        pop     cx
        ret
SumArray        endp
 
;обработка массива Array
;элементы, кратные четырём, уменьшить в четыре раза
ProcessArray    proc
        push    ax
        push    cx
        push    si
 
        mov     cx,     N
        lea     si,     Array
@@For:
        test    word ptr [si],  0003h
        jnz     @@Next
        sar     word ptr [si],  1
        sar     word ptr [si],  1
@@Next:
        add     si,     2
        loop    @@For
 
        pop     si
        pop     cx
        pop     ax
        ret
ProcessArray    endp
 
; выводит число из регистра AX на экран
; входные данные:
; ax - число для отображения
Show_AX proc
        push    ax
        push    bx
        push    cx
        push    dx
        push    di
 
        mov     cx, 10
        xor     di, di          ; di - кол. цифр в числе
 
        ; если число в ax отрицательное, то
        ;1) напечатать '-'
        ;2) сделать ax положительным
        or      ax, ax
        jns     @@Conv
        push    ax
        mov     dx, '-'
        mov     ah, 2           ; ah - функция вывода символа на экран
        int     21h
        pop     ax
 
        neg     ax
 
@@Conv:
        xor     dx, dx
        div     cx              ; dl = num mod 10
        add     dl, '0'         ; перевод в символьный формат
        inc     di
        push    dx              ; складываем в стэк
        or      ax, ax
        jnz     @@Conv
        ; выводим из стэка на экран
@@Show:
        pop     dx              ; dl = очередной символ
        mov     ah, 2           ; ah - функция вывода символа на экран
        int     21h
        dec     di              ; повторяем пока di<>0
        jnz     @@Show
 
        pop     di
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        ret
Show_AX endp
 
main    proc
        mov     ax,     @data
        mov     ds,     ax
 
        ; заполнение массива
        call    FillArray
        ; вывод массива на экран
        call    ShowArray
        ; вычисление суммы элеметов массива
        call    SumArray
        mov     Sum,    ax
        ; вывод сообщеия о значении суммы
        mov     ah,     09h
        lea     dx,     msgSum
        int     21h
        mov     ax,     Sum
        call    Show_AX
        mov     ah,     09h
        lea     dx,     msgCrLf
        int     21h
 
        ; обработка массива
        call    ProcessArray
        ; вывод массива на экран
        call    ShowArray
        ; вычисление суммы элеметов массива
        call    SumArray
        mov     Sum,    ax
        ; вывод сообщеия о значении суммы
        mov     ah,     09h
        lea     dx,     msgSum
        int     21h
        mov     ax,     Sum
        call    Show_AX
        mov     ah,     09h
        lea     dx,     msgCrLf
        int     21h
 
        mov     ax,     4C00h
        int     21h
main    endp
 
end     main

EXTERN printf: PROC
EXTERN ExitProcess: PROC
 
.data
num_fmt db "%d ",0
sum_msg db 10,"Sum of array elements: %d",10,0
 
.const
a0  dd 18
d   dd 43
count dd 10
shr_ar dd 4 dup (3)
 
.code
 
main proc
    push rbp
    sub rsp, 280
    lea rbp, [rsp+32]
 
    mov rcx, rbp
    call fill_array
    mov rcx, rbp
    call print_array
    mov rcx, rbp
    call sum
    mov rcx, rbp
    call process_array
    mov rcx, rbp
    call print_array
    mov rcx, rbp
    call sum
 
    lea rsp, [rbp+248]
    pop rbp
    call ExitProcess
main endp
 
fill_array proc
    mov eax, a0
    mov rdx, rcx
    movsxd rcx, count
f_l:
    mov [rdx], eax
    add eax, d
    add rdx, 4
    loop f_l
 
    ret
fill_array endp
 
sum proc
    sub rsp, 32
    movq mm0, [rcx]
    mov rdx, 1
s_l:
    paddd mm0, [rcx + 8*rdx]
    inc rdx
    cmp rdx, 5
    jl s_l
    phaddd mm0, mm1
 
    lea rcx, sum_msg
    movd rdx, mm0
    call printf
 
    add rsp, 32
    ret
sum endp
 
print_array proc
    push rbx
    push rdi
    sub rsp, 32
 
    mov rdi, rcx ; array address
    xor rbx, rbx ; index
p_l:
    lea rcx, num_fmt
    movsxd rdx, dword ptr [rdi + 4 * rbx]
    call printf
    inc rbx
    cmp rbx, 10
    jl p_l
 
    add rsp, 32
    pop rdi
    pop rbx
    ret
print_array endp
 
process_array proc
    sub rsp, 32
    mov rax, rcx
    mov rcx, 2
 
u_l:
    movdqu xmm0, xmmword ptr [rax]
    vpand xmm1, xmm0, shr_ar
    pcmpeqd xmm1, xmm2
    psrld xmm0, 2
    vmaskmovps [rax], xmm1, xmm0
    add rax, 16
    loop u_l
 
; remainder
    vmovq xmm0, qword ptr [rax]
    vpand xmm1, xmm0, shr_ar
    pcmpeqd xmm1, xmm2
    vmovq xmm2, xmm1
    psrld xmm0, 2
    vmaskmovps [rax], xmm2, xmm0
 
    add rsp, 32
    ret
process_array endp
 
end