Программа посчета нулей в числах и запись их в файл

@navchalkin · Регистрация: 20.04.2015

Author24 — интернет-сервис помощи студентам

Доброго времени суток.
Предупреждение - мой уровень ассемблера примерно равен 0. Особенностей этого языка не знаю, поэтому попрошу сильно не судить. Код мой, алгоритм тоже. Частично рабочий. Проблема в том, что заносит в файл В1, В2 и В3 только первое число, все остальные игнор.

задание: Разработать программу, которая отслеживает появление указанных цифр в числовом файле. Создать файл В1 с четырехзначных чисел путем ввода с клавиатуры, образуя файл В2 с цифр файла В1, имеющих один ноль, образуя файл В3 с цифр файла В1, имеющих два нуля и создать файл В4 с цифр файла В1, имеющих три нуля.
Готовый код у меня есть, только вот с самим занесением в файлы В2, В3, В4 проблема. Заносит только первое Четырехцифровое число в эти три файла, причем не обращает внимание на нуле. А должно было бы)
Комментируемый код:

Assembler

org 100h      
jmp start                        
                        
b1 db 'b1.txt',0  
b2 db 'b2.txt',0
b3 db 'b3.txt',0
b4 db 'b4.txt',0   
k db 0                          ;счетчик нулей
 
handle dw ? 
handleb2 dw ?
handleb3 dw ?
handleb4 dw ?  
 
bufer  db 50 DUP (?)     
bufer2 db 50 DUP (?)   
size  = $ - offset bufer     
size2 = $ - offset bufer2   
 
start:              
 
mov ax, cs
mov dx, ax
mov es, ax
 
mov ah, 3ch
mov cx, 0
mov dx, offset b1          ;создание файла В1
int 21h
mov handle, ax
 
;--------scan, check, write in file----------
       
level1:      
mov ah,1                                    
int 21h                         ;считывание чисел с клавиатури
mov dl,al        
                                     
cmp al,13                     ;проверка на Enter
je call write                  ;если да - переход на метку записи файла
 
mov [bufer+si], al         ;запис введеных даних в масив
add si, 1        
jne level1 
 
level2:
    call b2proc                
    call b3proc                ;создание 3-х файлов "В"
    call b4proc
    call read                   ;процедура считывания с файла В1
 
;---------------------------------------------------proc-------------- 
                                        
;------------write to file b1-----------                                        
write proc
    mov ah, 42h
    mov bx, handle
    mov al, 0
    mov cx, 0
    mov dx, 0
    int 21h
    inc k    
  
    mov ah, 40h
    mov bx, handle
    mov dx, offset bufer    ;Процедура записи в В1
    mov cx, size
    int 21h     
    
    mov ah, 3eh
    mov bx, handle
    int 21h     
write endp      
 
;-----------create file b2, b3, b4------------
              
b2proc proc
    mov ah, 3ch
    mov cx, 0
    mov dx, offset b2
    int 21h
    mov handleb2, ax                  
b2proc endp    
 
b3proc proc
    mov ah, 3ch
    mov cx, 0
    mov dx, offset b3        ;создание 3-х файлов В
    int 21h
    mov handleb3, ax                  
b3proc endp
 
b4proc proc
    mov ah, 3ch
    mov cx, 0
    mov dx, offset b4
    int 21h
    mov handleb4, ax                  
b4proc endp
         
;----------read the file b1---------         
         
read proc 
    MOV AH,3DH             
    MOV AL,0                      
    MOV DX,OFFSET b1    
    INT 21H                   
    MOV HANDLE, AX               
        
    MOV AH,3FH              
    MOV BX,HANDLE         
    MOV CX,512              
    MOV DX,OFFSET bufer   ;считывание с файла В1            
    INT 21H
    CMP AX,512   
read endp  
 
;----------main logic----------
 
compare proc                 ;цикл проверки считаних чисел с В1 і записи в другие файлы
    mov cx, 50
    mov si, 0 
    mov di, 0
  input:
    mov al, [bufer+si]        ;заносим в регистр al si-й член масива
   
    cmp al, 0                    ; проверяем на нуль
    je call increment          ; если 0 - инкрементуєм счетчик нуля
                        
    mov [bufer2+di],al   ;записываем символ в буфер 2
    inc si                      
    inc di                      
    cmp di, 4                 ; если di = 4 -
    je call crossroads      ; - вызываем процедуру "crossroads"
   loop input      
    
compare endp       
            
;----------inc k-----------           
            
increment proc
    inc k                            ;процедура инкремента счетчика нулей
increment endp
     
;----------crossroads----------  
 
crossroads proc                 ;
    
    cmp k, 1                      ;если к=1
    je call writeb2               ;вызываем запись в файл В2
    
    cmp k, 2                       ;если к=2
    je call writeb3                ;вызываем запись в файл В3 
    
    cmp k, 3                       ;если к=3
    je call writeb3                ;вызываем запись в файл В2 
 
    mov k, 0                        
    mov di, 0                      ;обнуляєм счетчики
    inc si                            ;инкремент си чтоб пропустить пробел 
                                       ;(числа в файл заносяться через "пробел")
crossroads endp   
                               
;---------write to files------------
 
;---------b2---------                              
writeb2 proc                      ;функции записи в файли числа с буфера2 
    mov ah, 42h
    mov bx, handleb2
    mov al, 0
    mov cx, 0
    mov dx, 0
    int 21h
    inc k    
  
    mov ah, 40h
    mov bx, handleb2
    mov dx, offset bufer2
    mov cx, size2
    int 21h     
    
    mov ah, 3eh
    mov bx, handleb2
    int 21h
writeb2 endp
           
;---------b3---------            
writeb3 proc
    mov ah, 42h
    mov bx, handleb3
    mov al, 0
    mov cx, 0
    mov dx, 0
    int 21h
    inc k    
  
    mov ah, 40h
    mov bx, handleb3
    mov dx, offset bufer2
    mov cx, size2
    int 21h     
    
    mov ah, 3eh
    mov bx, handleb3
    int 21h    
writeb3 endp
 
;---------b4--------- 
writeb4 proc
    mov ah, 42h
    mov bx, handleb4
    mov al, 0
    mov cx, 0
    mov dx, 0
    int 21h
    inc k    
  
    mov ah, 40h
    mov bx, handleb4
    mov dx, offset bufer2
    mov cx, size2
    int 21h     
    
    mov ah, 3eh
    mov bx, handleb4
    int 21h
writeb4 endp
 
ret

@R71MT · 11.04.2016, 12:55

navchalkin, чет ты размазал одинаковые функции по всему коду. Вполне можно создать одну и просто передавать ей параметры, типа имя/хэндлы и прочую лабуду. И чтобы записать в файл, необязательно его откравать. Достаточно создать его и потом записывать в него по-хэндлу (дескриптору).

Вот тебе код на FASM'e, решающий твою задачу:

Кликните здесь для просмотра всего текста

Assembler

org 100h
jmp start
 
mess0    db  13,10,'Enter string: $'
mess1    db  13,10,'All File Created! $'
 
fName    db  'b1.txt',0     ;
fSize    dw  0              ; длина строки
inBuff   db  80 dup(20h)    ; буфер для её хранения
hndl2    dw  0              ; хэндлы файлов В2,3,4
hndl3    dw  0              ;
hndl4    dw  0              ;
 
start:
   mov   ah,9               ; запрос на ввод
   mov   dx,mess0           ;
   int   21h                ;
   mov   di,inBuff          ; di для stosb
   xor   bx,bx              ; сбрасываем счётчик длины
input:                      ;
   mov   cx,4               ; число: 4 значное
   mov   ah,1               ; ввод с эхом
@@:                         ;
   int   21h                ; читаем клаву
   cmp   al,13              ; enter - закончить ввод
   je    next               ;
   stosb                    ; запись символа в di
   inc   bx                 ; считаем общую длину строки
   loop  @b                 ; читаем 4 символа
   mov   al,' '             ; вставляем пробел/разделитель
   int   29h                ;
   stosb                    ;
   inc   bx                 ;
   jmp   input              ;
;------------------------------------------------------------------
next:                       ;
   push  bx                 ; запомним длину строки
   mov   [fSize],bx         ;
   mov   dx,fName           ;
   call  createFile         ; создаём файл "В1.txt"
   jc    error              ; катапульта при ошибке
   pop   cx                 ; передаём параметры
   mov   bx,ax              ;    ..процедуре WriteFile
   mov   dx,inBuff          ;
   call  writeFile          ; данные в буфере! Эт файл нам больше не нужен
   call  closeFile          ;    ..закрываем "В1.txt"
;------------------------------------------------------------------
   mov   cx,3               ; создаём ещё 3 файла
   mov   bp,hndl2           ; указатель для сохранения дескрипторов
@@:                         ;
   inc   byte[fName+1]      ; меняем цифру в имени файла
   mov   dx,fName           ; 5
   call  createFile         ; 4
   mov   [bp],ax            ; 3
   inc   bp                 ; 2
   inc   bp                 ; 1
   loop  @b                 ; ПУСК! Есть ещё 3 файла с хэндлами.
;------------------------------------------------------------------
   mov   cx,[fSize]         ;
   shr   cx,2               ; СХ = длина строки в словах (длина/4)
   mov   di,inBuff          ; адрес строки
begin:                      ;
   push  cx                 ; сохраним счётчик внешнего цикла
   call  findNul            ; ищем кол-во нулей в очередном слове
   cmp   bx,1               ; один нуль в слове?
   jnz   file3              ; нет - пропускаем..
   mov   bx,[hndl2]         ; иначе: передаём хэндл файла "В2.txt"
   jmp   ok                 ; и прыгаем на запись в файл!
file3:                      ;
   cmp   bx,2               ; в слове два нуля?
   jnz   file4              ;
   mov   bx,[hndl3]         ;
   jmp   ok                 ;
file4:                      ;
   cmp   bx,3               ; три нуля?
   jnz   fuck               ; нет - материмся, и проверяем сл.слово
   mov   bx,[hndl4]         ;
ok:                         ; есть совпадения!
   mov   cx,5               ; 5 символов для записи (с пробелом)
   mov   dx,di              ; адрес найденного слова
   sub   dx,cx              ; прыг на его начало
   call  writeFile          ; пишем в файл!
fuck:                       ;
   pop   cx                 ; восстанавливаем счётчик циклов
   loop  begin              ; читаем следующее слово в строке..
;------------------------------------------------------------------
   mov   cx,3               ; закрываем все/три файла
   mov   ax,[hndl2]         ;
@@:                         ;
   mov   bx,ax              ;
   call  closeFile          ;
   add   ax,2               ; дескриптор сл.файла
   loop  @b                 ;
;------------------------------------------------------------------
   mov   ah,9               ; успешная мессага!
   mov   dx,mess1           ;
   int   21h                ;
   jmp   exit               ;
;------------------------------------------------------------------
error:                      ; обработчик ошибки.
   call  @f                 ;
   db    13,10,7,'<--File operation error!$'
@@:                         ;
   pop   dx                 ;
   mov   ah,9               ;
   int   21h                ;
;------------------------------------------------------------------
exit:                       ;
   xor   ax,ax              ;
   int   16h                ;
   int   20h                ; выход по-любой клавише
 
;~~~~~~~~~~~~8<~~~~~~~~~~~~~~ Нужные процедуры ~~~~~~~8<~~~~~~~~~~~~~~
createFile:                 ; создать! =========================//
   push  cx                 ;
   mov   ah,3Ch             ;
   mov   cx,20h             ;
   int   21h                ;
   pop   cx                 ;
ret
writeFile:                  ; запись! ==========================//
   push  cx                 ;
   mov   ah,40h             ;
   int   21h                ;
   pop   cx                 ;
ret
closeFile:                  ; закрыть! ==========================//
   mov   ah,3Eh             ;
   int   21h                ;
ret
findNul:                    ; поиск нулей в строке
   mov   cx,5               ; длина слова (с пробелом)
   xor   bx,bx              ; счётчик найденых
   mov   al,'0'             ; искать будем нуль
@@:                         ;
   repne scasb              ; поиск пошёл..
   or    cx,cx              ; конец строки?
   jz    @f                 ;
   inc   bx                 ; нет - считаем нули
   jmp   @b                 ;
@@:                         ;
ret                         ;

@navchalkin · 12.04.2016, 15:15 **[ТС]**

R71MT, супер, все работает. Очень благодарен.
У меня еще несколько вопросов по программе:
1) у вас метки @@ и потом вы на них возвращаетесь через @b, это как так?
2)

Assembler

1	inc byte[b1+1] ; как такую штуку сделать в ТАСМ или МАСМ?

Добавлено через 54 минуты

Assembler

1	inc byte[b1+1] ; как такую штуку сделать в ТАСМ или МАСМ?

Этот вопрос решил, как я понял, оно заменяет второй символ в тексте. Если например текст был бы не b1.txt а file1.txt, оно заменило бы "i" на "j"
в ТАСМе синтаксис похож, только добавляется еще Ptr

Assembler

1	inc Byte Ptr [b1+1]

Остался вопрос с метками

@R71MT · 12.04.2016, 16:15

1. Fasm manual. 1.2.3 Константы и метки

"@@" обозначает анонимную метку, вы можете определить её множество раз.
Символ "@b" (или эквивалент "@r") ссылается на ближайшую предшествующую анонимную метку,
а символ "@f" ссылается на ближайшую после неё анонимною метку.
Эти специальные символы нечувствительны к регистру.

2. Можно обращаться к каждому байту имени файла указав смещение от начала имени.
Соответственно, чтоб сменить имя "file1" на "file2" нужно инкременировать 4-ый байт (отсчёт с нуля):

Assembler

1	inc Byte Ptr [b1+4]

@navchalkin · 15.04.2016, 23:11 **[ТС]**

Сообщение от R71MT

inc Byte Ptr [b1+4]

мне нужно что-то вроде этого, только для того чтобы менять не данные в переменной, а саму переменную, а то этот кусок кода:

Assembler

 mov   cx,3               ; создаём ещё 3 файла
   mov   bp,hndl2           ; указатель для сохранения дескрипторов
@@:                         ;
   inc   byte[fName+1]      ; меняем цифру в имени файла
   mov   dx,fName           ; 5
   call  createFile         ; 4
   mov   [bp],ax            ; 3
   inc   bp                 ; 2
   inc   bp                 ; 1
   loop  @b                 ; ПУСК! Есть ещё 3 файла с хэндлами.

в ТАСМ не работает. в хендлак пусто

@R71MT · 16.04.2016, 01:08

..на фасме всё работает. Пройдись отладчиком по-этому участку и посмотри где и почему тормозит.

@navchalkin · 18.04.2016, 08:11 **[ТС]**

Переписал код, в одном месте (с хендлами) пришлось сделать три процедуры, но радует сам факт того что она заработала. Работал в Emu8086

Assembler

.model small
.stack 256
.data      
 
msg0  db 13,10,'Enter number: $'  
 
b1    db 'b1.txt',0  
sizeB dw 0             
 
hndl2 dw 0
hndl3 dw 0
hndl4 dw 0
var   dw 0    
 
bufer db 80 DUP (?)     
 
.code
    assume ds:@data, es:@data, cs:@code
 
start:
    
    mov   ax,@data
    mov   ds,ax
    mov   es,ax
 
;\
; >-----\/----- enter the keyboard -----\/-----
;/                    
    mov   ah, 9             ;
    int   21h               ;
    mov   di, offset bufer  ;
    xor   bx, bx            ;
                            ;
level1:                     ;
    mov   cx, 4             ;
    mov   ah, 1             ;                           ;
@@:                         ; cykl vvodu 4 symboliv
    int   21h               ;
    cmp   al, 13            ;
    je    level2            ;
    stosb                   ;
    inc   bx                ;
loop @@                     ;
                            ;
    mov   ah, 2             ;
    mov   dl, ' '           ; pislya 4 symboliv stavum propusk 
    int   21h               ;
    stosb                   ;
    inc   bx                ;
    jmp   level1            ; i prodovzhuem vvid z klaviatury
 
 
;\
; >-----\/----- create file, compare number -----\/-----
;/
 
level2:  
    push  bx                ;
    mov   [sizeB], bx       ;
    mov   dx, offset b1     ;
                            ;
    call  createFile        ;   
    pop   cx                ;
    mov   bx,ax             ;
    mov   dx, offset bufer  ; 
                            ;
    call  writeFile         ; 
    call  closeFile         ;
    
;-----------------------------
    mov   cx, 3             ;
    mov   bp, hndl2  ;  
@1:                         ;
    inc   Byte Ptr [b1+1]   ;
    mov   dx, offset b1     ;
    call  createFile        ;
    
    cmp   cx, 3
    je    hd2
    cmp   cx, 2
    je    hd3
    cmp   cx, 1
    je    hd4   
    cmp   cx, 0
    loop  @1                ;
                            ;
;-------------------------- ;
@5:
    mov   cx, [sizeB]  ;
    shr   cx, 2             ;
    mov   di, offset bufer  ;
                            ;
begin:                      ;
    push  cx                ;
    call  FindNull          ;
    cont:         
    mov   var, bx   ;
    cmp   bx, 1             ;
    jnz   file3             ;
    mov   bx, hndl2  ;
    jmp   ok                ;
                            ;
file3:                      ;
    cmp   bx, 2             ;
    jnz   file4             ;
    mov   bx, hndl3  ;
    jmp   ok                ;
                            ;
file4:                      ;
    cmp   bx, 3             ;
    jnz   error             ;
    mov   bx, hndl4  ;
ok:                         ;
    mov   cx, 5             ;
    mov   dx, di            ;
    sub   dx, cx            ;
    call  writeFile         ;
error:                      ;
    pop   cx                ;
    loop  begin             ;
                            ;
;---------------------------;-----------
                            ;
    mov   cx, 3             ;
    mov   ax, offset hndl2  ;
@3:                         ;
    mov   bx, ax            ;
    call  CloseFile         ;
    add   ax, 2             ;
    loop  @3                ;
                            ;
    jmp   exit              ;
                            ;
;------------------PROCEDURE;---------------
                            ;
createFile:                 ;
    push  cx                ;
    mov   ah, 3ch           ;
    mov   cx, 20h           ;
    int   21h               ;
    pop   cx                ;
ret                         ;
                            ;
writeFile:                  ;
    push  cx                ;
    mov   ah, 40h           ;
    int   21h               ;
    pop   cx                ;
ret                         ;
                            ;
closeFile:                  ;
    mov   ah, 3eh           ;
    int   21h               ;
ret                         ;
                            ;
FindNull:                   ;
    mov   cx, 5             ;
    xor   bx, bx            ;
    mov   al, '0'           ;
@2:                         ;
    repne scasb             ;
    jcxz    endpro          ;
    inc   bx                ;
    jmp   @2                ;
endpro:
ret     
 
;-----------------------------
hd2:
    mov hndl2, ax
        dec   cx 
        jmp @1
ret
hd3:
    mov hndl3, ax           ;\  
        dec   cx            ; > Write HANDLE
        jmp @1              ;/
ret 
hd4:
    mov hndl4, ax
        dec   cx 
        jmp @5
ret
;--------------------------------
exit:                       ;
    xor   ax,ax             ;
    int   16h               ;
    int   20h               ;
                            ;
end start                   ;

@R71MT · 18.04.2016, 09:02

Сообщение от navchalkin

пришлось сделать три процедуры

..ну это нормально. Сегодня сделал 3, завтра - 2, а потом глядишь и вообще без них обойдёшься. Практика рулит!

Программа посчета нулей в числах и запись их в файл

Решение

Решение

@R71MT Эксперт Hardware 6160 / 2397 / 398 Регистрация: 29.07.2014 Сообщений: 3,143 Записей в блоге: 4
	16.04.2016, 01:08	6
	..на фасме всё работает. Пройдись отладчиком по-этому участку и посмотри где и почему тормозит. 0

@R71MT Эксперт Hardware 6160 / 2397 / 398 Регистрация: 29.07.2014 Сообщений: 3,143 Записей в блоге: 4
	18.04.2016, 09:02	8
	Сообщение от navchalkin пришлось сделать три процедуры ..ну это нормально. Сегодня сделал 3, завтра - 2, а потом глядишь и вообще без них обойдёшься. Практика рулит! 1