Подсчет остатков

@Londreik · Регистрация: 05.09.2013

Author24 — интернет-сервис помощи студентам

Здравствуйте
У меня есть регистр накопления и документ списания, надо сделать так, чтобы в отчете на основе регистра (впрочем и в самом регистре) не было значений меньше 0 (т.е. были только положительные числа).
Сам код:

1C

Для Каждого ТекСтрокаТовары Из Товары Цикл
      Запрос = Новый Запрос("ВЫБРАТЬ
                            | ТоварыНаСкладахОстатки.КоличествоОстаток,
                            | ТоварыНаСкладахОстатки.Номенклатура,
                            | ТоварыНаСкладахОстатки.Состояние,
                            | СУММА(СписаниеТоваровТовары.Количество) КАК Количество,
                            | СписаниеТоваровТовары.Номенклатура КАК Номенклатура1,
                            | СписаниеТоваровТовары.Состояние КАК Состояние1
                            |ИЗ
                            | РегистрНакопления.ТоварыНаСкладах.Остатки(
                            |     &ДатаСреза,
                            |     Номенклатура = &Номенклатура
                            |       И РабочиеМеста = &РабочиеМеста) КАК ТоварыНаСкладахОстатки,
                            | Документ.СписаниеТоваров.Товары КАК СписаниеТоваровТовары
                            |
                            |СГРУППИРОВАТЬ ПО
                            | ТоварыНаСкладахОстатки.КоличествоОстаток,
                            | ТоварыНаСкладахОстатки.Номенклатура,
                            | ТоварыНаСкладахОстатки.Состояние,
                            | СписаниеТоваровТовары.Номенклатура,
                            | СписаниеТоваровТовары.Состояние");
      
      ОстатокНаСкладе = 0;
      Количество = 0;
      Запрос.УстановитьПараметр("ДатаСреза", Новый Граница(ЭтотОбъект.МоментВремени(), ВидГраницы.Исключая));
      Запрос.УстановитьПараметр("Номенклатура", ТекСтрокаТовары.Номенклатура);
      Запрос.УстановитьПараметр("РабочиеМеста", РабочиеМеста);
      Запрос.УстановитьПараметр("Состояние", ТекСтрокаТовары.Состояние);
      ВыбРез = Запрос.Выполнить().Выбрать();
      Если ВыбРез.Следующий() Тогда
        ОстатокНаСкладе = ВыбРез.КоличествоОстаток;
        Количество = ВыбРез.Количество;
      КонецЕсли;
      Если ОстатокНаСкладе < Количество Тогда
        Сообщить("Не хватает " + ТекСтрокаТовары.Номенклатура + ". На складе " + ОстатокНаСкладе + " в документе " + Количество);
        Отказ = Истина;
        Возврат;
      КонецЕсли; 
      Движение = Движения.ТоварыНаСкладах.Добавить();
      Движение.ВидДвижения = ВидДвиженияНакопления.Расход;
      Движение.Период = Дата;
      Движение.Номенклатура = ТекСтрокаТовары.Номенклатура;
      Движение.РабочиеМеста = РабочиеМеста;
      Движение.Количество = ТекСтрокаТовары.Количество;
      Движение.Состояние = ТекСтрокаТовары.Состояние;
    КонецЦикла;

Где косяк? Все работает, т.е. идет проверка, но если указать несколько наименований в привязанной форме списания а именно
[Наименование_1
[Наименование_2
[Наименование_1
то игнорируется последнее наименование и все последующие первые наименования ("Наименование_1"). Если добавить третье, то первые два будут игнорироваться и их остатки проверяться уже не будут.
Код прописан в Процедуре Обработки Проведения формы.

@SonicQ · 05.09.2013, 12:19

Сообщение от Londreik

Наименование_1

на форме можно задать список значений? то есть выбрать несколько номенклатур?

@Joker_vad · 05.09.2013, 12:44

Сначала группирую табличную часть товары, потом связывай с регистром и смотри остатки

@Londreik · 05.09.2013, 12:45 **[ТС]**

Сообщение от SonicQ

на форме можно задать список значений? то есть выбрать несколько номенклатур?

Да, номенклатуры заполняются из справочника в табличном поле документа.
Спасибо, уже решено. Решилось все установлением правильных условий и соединений в запросе, так же вынесли из под цикла проверку.
Код, если интересно:

1C

  Если Константы.ВыводОтрицательныхЗначений.Получить() = Ложь Тогда
      Запрос = Новый Запрос("ВЫБРАТЬ
                            | ВложенныйЗапрос.Номенклатура,
                            | ВложенныйЗапрос.Состояние,
                            | ВложенныйЗапрос.Количество КАК КоличествоВДокументе,
                            | ЕСТЬNULL(ТоварыНаСкладахОстатки.КоличествоОстаток, 0) КАК КоличествоОстаток,
                            | ЕСТЬNULL(ТоварыНаСкладахОстатки.КоличествоОстаток, 0) - ВложенныйЗапрос.Количество КАК Разность
                            |ИЗ
                            | (ВЫБРАТЬ
                            |   СписаниеТоваровТовары.Номенклатура КАК Номенклатура,
                            |   СУММА(СписаниеТоваровТовары.Количество) КАК Количество,
                            |   СписаниеТоваровТовары.Состояние КАК Состояние
                            | ИЗ
                            |   Документ.СписаниеТоваров.Товары КАК СписаниеТоваровТовары
                            | ГДЕ
                            |   СписаниеТоваровТовары.Ссылка = &НашДокумент
                            | 
                            | СГРУППИРОВАТЬ ПО
                            |   СписаниеТоваровТовары.Номенклатура,
                            |   СписаниеТоваровТовары.Состояние) КАК ВложенныйЗапрос
                            |   ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ТоварыНаСкладах.Остатки(&ДатаСреза, РабочиеМеста = &РабочиеМеста) КАК ТоварыНаСкладахОстатки
                            |   ПО ВложенныйЗапрос.Номенклатура = ТоварыНаСкладахОстатки.Номенклатура
                            |     И ВложенныйЗапрос.Состояние = ТоварыНаСкладахОстатки.Состояние");
      Запрос.УстановитьПараметр("ДатаСреза", Новый Граница(ЭтотОбъект.МоментВремени(), ВидГраницы.Исключая));                       
      Запрос.УстановитьПараметр("РабочиеМеста", РабочиеМеста);
      Запрос.УстановитьПараметр("НашДокумент", Ссылка);
    
      ВыбРез = Запрос.Выполнить().Выбрать();
      Пока ВыбРез.Следующий() Цикл
        Если ВыбРез.Разность < 0 Тогда
          Сообщить("Не хватает номенклатуры " + ВыбРез.Номенклатура + " " + ВыбРез.Состояние + ". На рабочем месте " + ВыбРез.КоличествоОстаток + " в документе " + ВыбРез.КоличествоВДокументе);
          Отказ = Истина;  
        КонецЕсли;  
      КонецЦикла;
    КонецЕсли;
    
    Если Не Отказ Тогда
      Для Каждого ТекСтрокаТовары Из Товары Цикл
        Движение = Движения.ТоварыНаСкладах.Добавить();
        Движение.ВидДвижения = ВидДвиженияНакопления.Расход;
        Движение.Период = Дата;
        Движение.Номенклатура = ТекСтрокаТовары.Номенклатура;
        Движение.РабочиеМеста = РабочиеМеста;
        Движение.Количество = ТекСтрокаТовары.Количество;
        Движение.Состояние = ТекСтрокаТовары.Состояние;
      КонецЦикла;
    КонецЕсли;

Тему закрыть

Добавлено через 31 секунду

Сообщение от Joker_vad

Сначала группирую табличную часть товары, потом связывай с регистром и смотри остатки

Уже) Если бы пораньше написал) Спасибо

@Joker_vad · 05.09.2013, 12:49

Запрос в цикле то зачем, тут без него можно обойтись

Добавлено через 1 минуту
Всегда старайся избегать запроса в цикле, я помню как меня "по головке погладили" за такое)

Добавлено через 1 минуту
А вложенный запрос зачем, когда через виртуальные таблицы сделать можно? на 8,2 делаешь?

@Londreik · 05.09.2013, 12:51 **[ТС]**

Сообщение от Joker_vad

А вложенный запрос зачем, когда через виртуальные таблицы сделать можно? на 8,2 делаешь?

8.1
В плане через виртуальные таблицы? По подробней, пожалуйста

@Joker_vad · 05.09.2013, 12:56

через во это

@Londreik · 05.09.2013, 13:02 **[ТС]**

Тогда надо будет делать ссылку на документ в самом запросе? И каждый раз во временную выносить не тягостно будет, ежели можно организовать во внутреннем один раз? Может я заблуждаюсь, просто..

@Xomych · 05.09.2013, 13:04

Зачем сложно так?
Я так делаю.

1C

Движения.ОстаткиТоваров.Записывать = Истина;
    ТЧ=Товары.Выгрузить();
    ТЧ.Свернуть("Товар","Количество"); //сворачиваем табл. часть по номенклатуре
    Для Каждого ТекСтрокаТовары Из ТЧ Цикл
        Ост=0;
        Тов=ТекСтрокаТовары.Товар;
        Кол=ТекСтрокаТовары.Количество;
        
        Фильтр   = Новый Структура;
        Фильтр.Вставить("Товар", Тов);
        Фильтр.Вставить("Склад", Склад);
        ТблОст=РегистрыНакопления.ОстаткиТоваров.Остатки(,Фильтр,"Товар,Склад","Количество");
        for each ТблСтр in ТблОст do //у меня в таблице 1 строка
            Ост=ТблСтр.Количество;
        enddo;
        //получили остаток
        if Кол>Ост then 
                      //даем отлуп
                      Отказ=Истина;
                      break; 
                endif;
        //тут добавляем запись регистра накопления
    КонецЦикла;

@Joker_vad · 05.09.2013, 13:06

Сообщение от Londreik

Тогда надо будет делать ссылку на документ в самом запросе?

Вот это не понял. На сколько мне известно, вы выполните запрос по группировки табличной части только один раз и сохраните его в виртуальной таблице. Сейчас же этот запрос выполняется для каждой строки, что как раз таки я тягостно. Использование виртуальных таблиц оптимальнее

@Londreik · 05.09.2013, 13:09 **[ТС]**

Сообщение от Joker_vad

На сколько мне известно, вы выполните запрос по группировки табличной части только один раз и сохраните его в виртуальной таблице. Сейчас же этот запрос выполняется для каждой строки, что как раз таки я тягостно. Использование виртуальных таблиц оптимальнее

Хорошо, попробую

@Joker_vad 476 / 413 / 93 Регистрация: 26.09.2012 Сообщений: 1,920
	05.09.2013, 13:06	10
	Сообщение от Londreik Тогда надо будет делать ссылку на документ в самом запросе? Вот это не понял. На сколько мне известно, вы выполните запрос по группировки табличной части только один раз и сохраните его в виртуальной таблице. Сейчас же этот запрос выполняется для каждой строки, что как раз таки я тягостно. Использование виртуальных таблиц оптимальнее 1

@Londreik 11 / 11 / 1 Регистрация: 05.09.2013 Сообщений: 48
	05.09.2013, 13:09 [ТС]	11
	Сообщение от Joker_vad На сколько мне известно, вы выполните запрос по группировки табличной части только один раз и сохраните его в виртуальной таблице. Сейчас же этот запрос выполняется для каждой строки, что как раз таки я тягостно. Использование виртуальных таблиц оптимальнее Хорошо, попробую 0

@SonicQ 286 / 186 / 18 Регистрация: 20.02.2012 Сообщений: 926
	05.09.2013, 12:19	2
	Сообщение от Londreik Наименование_1 на форме можно задать список значений? то есть выбрать несколько номенклатур? 0

@Joker_vad 476 / 413 / 93 Регистрация: 26.09.2012 Сообщений: 1,920
	05.09.2013, 12:44	3
	Сначала группирую табличную часть товары, потом связывай с регистром и смотри остатки 1

@Joker_vad 476 / 413 / 93 Регистрация: 26.09.2012 Сообщений: 1,920
	05.09.2013, 12:49	5
	Запрос в цикле то зачем, тут без него можно обойтись Добавлено через 1 минуту Всегда старайся избегать запроса в цикле, я помню как меня "по головке погладили" за такое) Добавлено через 1 минуту А вложенный запрос зачем, когда через виртуальные таблицы сделать можно? на 8,2 делаешь? 1

@Londreik 11 / 11 / 1 Регистрация: 05.09.2013 Сообщений: 48
	05.09.2013, 12:51 [ТС]	6
	Сообщение от Joker_vad А вложенный запрос зачем, когда через виртуальные таблицы сделать можно? на 8,2 делаешь? 8.1 В плане через виртуальные таблицы? По подробней, пожалуйста 0

@Joker_vad 476 / 413 / 93 Регистрация: 26.09.2012 Сообщений: 1,920
	05.09.2013, 12:56	7
	через во это 0

@Londreik 11 / 11 / 1 Регистрация: 05.09.2013 Сообщений: 48
	05.09.2013, 13:02 [ТС]	8
	Тогда надо будет делать ссылку на документ в самом запросе? И каждый раз во временную выносить не тягостно будет, ежели можно организовать во внутреннем один раз? Может я заблуждаюсь, просто.. 0