Ключи запуска программ, вспомогательные утилиты (Windows Resource Kit, Support Tools)

:: сайт прграммы [url]http://www.utorrent.com/intl/ru[/url]
:: Загрузка [url]http://www.utorrent.com/intl/ru/downloads/complete/os/win/track/stable[/url]
:: языковой пакет [url]http://www.utorrent.com/scripts/dl.php?track=stable&build=37951&client=utorrent[/url]
::[url]http://download-new.utorrent.com/os/windows/track/stable/endpoint/utorrent[/url]
 
@echo off
setlocal enabledelayedexpansion
color 1a
 
:: Определяем наличие прокси, если есть, создаём файл ini
if exist tools\wget.ini del /q tools\wget.ini 1>nul
 
SET UNISTALL=HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings
for /f "tokens=2*" %%i in ('reg.exe query "%UNISTALL%" ^|find.exe /i "ProxyEnable"') do set Proksi=%%j
for /f "tokens=2*" %%a in ('reg.exe query "%UNISTALL%" ^|find.exe /i "ProxyServer"') do set IP=%%b
 
if "%Proksi%"=="0x1" (
>> tools\wget.ini Echo http_proxy = %IP%
>> tools\wget.ini Echo use_proxy = on
)
 
:: создаём временные папки
if exist TempZ\unpack rd /s /q TempZ\unpack
md TempZ\unpack 2>nul
 
:: адрес на скачивание стабильной версии
set sURLP=http://download-new.utorrent.com/os/windows/track/stable/endpoint/utorrent
 
:: качаем основной файл
echo.
set /p uSel1="Загрузить utorrent из интернет? [Enter - нет, 1 - да, 9 - выход] "
Echo.
if "%uSel1%"=="9" (goto :_DelTemp& exit /b)
If "%uSel1%"=="1" (tools\wget.exe -N -P "TempZ\unpack" "%sURLP%" 1>nul 2>&1& ren "%~dp0TempZ\unpack\utorrent" utorrent.exe >nul)
 
:: качаем файл локализации @ComSpec _https://www.cyberforum.ru/cmd-bat/thread1284369.html
set "dir=TempZ\unpack"
set "url=http://www.utorrent.com/scripts/dl.php?track=stable&build=37951&client=utorrent"
 
2>nul md "%dir%"
>.vbs (
echo Set x=CreateObject("MSXML2.XMLHTTP"^)
echo x.Open "GET","%url%",False
for %%i in (
 "x.Send"
 "If x.Status=200 Then"
 " With CreateObject("ADODB.Stream")"
 "  .Open"
 "  .Type=1"
 "  .Write x.ResponseBody"
 "  .Position=0"
 "  .SaveToFile "%dir%\utorrent.lng",2"
 "  .Close"
 " End With"
 "End If"
 ) do @echo %%~i
)
 
cscript //nologo .vbs& del .vbs
 
:: делаем нулевой файл настроек (необходим для создания портабельной версии)
type nul > "%~dp0TempZ\unpack\settings.dat"
 
Echo.
Echo.
 
:: Определяем версию скачанной программы
for /f "tokens=1* usebackq" %%a in (`tools\filever.exe /V "TempZ\unpack\utorrent.exe" ^| FIND "FileVersion"`) do set vrs=%%b
 
:: Правка файла настройки - замена версии на актуальную
Echo Копирование файла настроек...
copy /y "tools\settings.dat" "TempZ\unpack\" 1>nul
 
:: пишем inf
Echo Создание inf...
(Echo [Version]
Echo Signature="$Windows NT$"
Echo.
Echo [DefaultInstall]
Echo AddReg         =PROG.AddReg
Echo ProfileItems   =PROG.AddShortcut1,PROG.AddShortcut2
Echo.
Echo [Uninstall]
Echo BeginPrompt        =BeginUnInsPrompt
Echo RunPreSetupCommands    =Close.Prog:1
Echo RunPostSetupCommands    =Dir.Delete:1,File.Delete:1
Echo EndPrompt      =EndUnInsPrompt
Echo DelReg         =PROG.DelReg
Echo ProfileItems           =PROG.DelShortcut1,PROG.DelShortcut2
Echo.
Echo [BeginUnInsPrompt] 
Echo Title          =Деинсталляция %%PROG_NAME%%
Echo Prompt         =Вы действительно хотите удалить %%PROG_NAME%% и все компоненты программы? 
Echo ButtonType     =YESNO
Echo.
Echo [Close.Prog]
Echo TASKKILL /F /IM %%PROG_1%%
Echo.
Echo [Dir.Delete]
Echo rundll32.exe advpack.dll,DelNodeRunDLL32 "%%16422%%\%%PROG_DIR%%"
Echo rundll32.exe advpack.dll,DelNodeRunDLL32 "%%16410%%\%%PROG_DIR%%"
Echo.
Echo [File.Delete]
Echo cmd.exe /c "Del /q /f %%17%%\%%NAME_INF%%.*"
Echo.
Echo [EndUnInsPrompt]
Echo Prompt         =Программа %%PROG_NAME%% удалена.
Echo.
Echo [PROG.AddReg]
Echo HKLM,"%%KEY_UNINST%%","DisplayIcon",0,"%%16422%%\%%PROG_DIR%%\%%PROG_1%%"
Echo HKLM,"%%KEY_UNINST%%","DisplayName",,"%%PROG_NAME%%"
Echo HKLM,"%%KEY_UNINST%%","Publisher",,"%%PROG_MADE%%"
Echo HKLM,"%%KEY_UNINST%%","UninstallString",,"rundll32 advpack,LaunchINFSection %%17%%\%%NAME_INF%%.inf,Uninstall"
Echo.
Echo [PROG.DelReg]
Echo HKLM,"%%KEY_UNINST%%"
Echo.
Echo [PROG.AddShortcut1] 
Echo Name   =%%SRTC_NAME%%
Echo CmdLine    =16422,%%PROG_DIR%%,%%PROG_1%%
Echo WorkingDir =16422,%%PROG_DIR%%
Echo SubDir =%%PROG_SDIR1%%
Echo InfoTip    =%%PROG_INFO%%
Echo.
Echo [PROG.AddShortcut2] 
Echo Name   =%%SRTC_NAME%%,0x00000001
Echo CmdLine    =16422,%%PROG_DIR%%,%%PROG_1%%
Echo WorkingDir =16422,%%PROG_DIR%%
Echo SubDir =%%PROG_SDIR2%%
Echo InfoTip    =%%PROG_INFO%%
Echo.
Echo [PROG.DelShortcut1]
Echo Name       =%%SRTC_NAME%%,0x00000002
Echo SubDir =%%PROG_SDIR1%%
Echo.
Echo [PROG.DelShortcut2]
Echo Name       =%%SRTC_NAME%%,0x00000003
Echo SubDir =%%PROG_SDIR2%%
Echo.
Echo [Strings]
Echo PROG_DIR   ="utorrent"
Echo PROG_NAME  ="utorrent v.%vrs%"
Echo SRTC_NAME  ="utorrent"
Echo PROG_VERS  ="%vrs%"
Echo PROG_MADE  ="oszone.net"
Echo NAME_INF   ="utorrent"
Echo PROG_1 ="utorrent.exe"
Echo PROG_INFO  ="торрент трекер"
Echo PROG_SDIR1 ="Утилиты")>TempZ\866.txt
Call :_ChCp CP1251 TempZ\unpack\utorrent.inf
 
::пишем QLP.cmd
Echo Создание QLP.cmd...
(Echo ChCp 1251^>Nul
Echo Ver ^| Find "6.1" ^>Nul ^|^| (
Echo Echo PROG_SDIR2="..\..\Application Data\Microsoft\Internet Explorer\Quick Launch"
Echo ^)^>^>%%NameInf%%
Echo Ver ^| Find "6." ^>Nul ^&^& (
Echo Echo PROG_SDIR2    ="..\..\..\..\..\..\AppData\Roaming\Microsoft\Internet Explorer\Quick Launch"
Echo ^)^>^>%%NameInf%%
Echo ChCp 866^>Nul)>TempZ\866.txt
Call :_ChCp CP1251 TempZ\unpack\QLP.cmd
 
:: пишем Win64.cmd
Echo Создание Win64.cmd...
(Echo @echo off
Echo setlocal EnableDelayedExpansion
Echo.
Echo Set xOS=x86^& If Defined PROCESSOR_ARCHITEW6432 ^(Set xOS=x64^) Else If "%%PROCESSOR_ARCHITECTURE%%"=="AMD64" Set xOS=x64
Echo.
Echo set UNINST=utorrent
Echo set filename=utorrent.inf
Echo set $filename=utorrent-1.inf
Echo.
Echo set in=KEY_UNINST  ="Software\Microsoft\Windows\CurrentVersion\Uninstall\%%UNINST%%"
Echo set out=KEY_UNINST ="Software\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\%%UNINST%%"
Echo.
Echo if "%%xOS%%"=="x64" ^(
Echo    for /f "tokens=1* delims=]" %%%%A in ^(^'find /v /n ^"^" ^^^<^"%%filename%%^"^'^) do ^(
Echo        set line=%%%%B
Echo        if defined line ^(set line=^^!line:16422=16426^^!^)
Echo        if "^!line^!"=="%%in%%" ^(echo %%out%%^>^>%%$filename%%^) else ^(echo^.^^!line^^!^>^>%%$filename%%^)
Echo        ^)
Echo    del /q %%filename%%
Echo    ren "%%$filename%%" "%%filename%%"
Echo    ^>^>%%filename%% echo %%out%% 
Echo    ^) else ^(
Echo    ^>^>%%filename%% echo %%in%% 
Echo ^) 
Echo exit /b)>>TempZ\866.txt
Call :_ChCp CP866 TempZ\unpack\Win64.cmd
 
:: Пишем конфиг для sfx
Echo Создание конфиг для sfx...
(Echo ;^^!@Install@^^!UTF-8^^!
Echo SetEnvironment="Name=utorrent"
Echo SetEnvironment="fVer=%vrs%"
Echo SetEnvironment="NameInf=utorrent.inf"
Echo Title="Установка %%Name%%"
Echo BeginPrompt="Сейчас будет установлен %%Name%% v.%%fVer%% [%%%%P]"
Echo ExtractTitle="Распаковка файлов..."
Echo ExtractDialogText="Придется подождать..."
Echo FinishMessage="%%Name%% v.%%fVer%% ^[%%%%P^] установлен^!"
Echo InstallPath="%%ProgramFiles%%\\%%Name%%"
Echo RunProgram="hidcon:QLP.cmd"
Echo RunProgram="hidcon:Win64.cmd"
Echo RunProgram="fm5:hidcon:cmd /c Move %%NameInf%% %%WINDIR%%\\INF"
Echo RunProgram="rundll32 advpack,LaunchINFSection %%NameInf%%,DefaultInstall,0"
Echo Delete="%%%%T\\QLP.cmd"
Echo Delete="%%%%T\\Win64.cmd"
Echo GUIFlags="2+4+8+16+32+2048+4096"
Echo GUIMode="1"
Echo SfxAuthor="sov44"
ECho ;^^!@InstallEnd@^^!)>TempZ\866.Txt
Call :_ChCp utf8 Tempz\utorrent.txt
 
:: пишем свойства sfx модуля
Echo Редактирование модуля sfx.
 
copy /y "Tools\7zsd_LZMA2.sfx" "TempZ\utorrent.sfx" 1>nul
 
Tools\7zsdrc.exe TempZ\utorrent.sfx ^
-i Tools\Icon_1.ico ^
-pv "%vrs%" ^
-fv "%vrs%" ^
-vs "ProductVersion=3.4.3.4" ^
-vs "Comments=Создание скриншотов, редактирование" ^
-vs "CompanyName=utorrent" ^
-vs "FileDescription=торрент-трекер" ^
-vs "LegalCopyright=" ^
-vs "LegalTrademarks=sov44" ^
-vs "OriginalFilename=utorrent_%vrs%.exe" ^
-vs "ProductName=utorrent"
 
echo Создание SFX...
>nul tools\7z.exe a TempZ\utorrent.7z -m0=LZMA2 -mx=9 -mmt=2 .\TempZ\unpack\*
>nul copy /b TempZ\utorrent.sfx+TempZ\utorrent.txt+TempZ\utorrent.7z "utorrent_%vrs%.exe"
 
Echo.
Echo.
 
set /p adn="Инсталлятор или аддон?  [Enter - инсталлятор, 2 - аддон] " 
if defined adn (
md utorrent\Files\ForceCopy\SVCPACK
move /y "utorrent_%vrs%.exe" "utorrent\Files\ForceCopy\SVCPACK\utorrent.exe" >nul
 
echo.
echo Созданеие файлов аддона:
echo Пишем Run...
(Echo.
Echo utorrent.exe -y -gm2 -fm0)>utorrent\Run
 
echo Пишем Addon.nfo...
(Echo Аддон utorrent
Echo Версия v.%vrs%
Echo Совместим с UpdatePack-XPSP3-Rus
Echo Тип интеграции аддона: SVCPACK
Echo.
Echo Ключ тихой установки: -y -gm2 -fm0
Echo.
Echo by sov44
Echo %Date%)>TempZ\866.txt
Call :_ChCp CP1251 utorrent\Addon.nfo
 
echo Пакуем аддон...
tools\7z.exe a utorrent_%Vrs%_addon.7z -m0=LZMA2 -mx=9 -mmt=2 utorrent>nul
 
echo Создание аддона завершено^^!
) else echo.& echo.& echo Создание utorrent_%vrs%.exe завершено^^!
 
Echo.
Echo Для удаления временных файлов и выхода нажмите любую клавишу.
pause>nul
Echo.
 
:_DelTemp
rd /s /q TempZ >nul
rd /s /q utorrent 2>nul 1>&2
 
::if exist TempZ GoTo :_DelTemp
::GoTo :EOF
endlocal
exit /b
 
:: конвертер текстовых файлов
:_ChCp
tools\win_iconv.exe -f CP866 -t %~1 TempZ\866.txt >"%~2"
Del /Q/F TempZ\866.txt 2>Nul
GoTo :EOF