Вопрос в стиле "Разрушители мифов"

.586
.model flat
include windows.inc
includelib user32.lib
extern _imp__MessageBoxA@16:dword
.code
start:  fld x
        xchg ebx,eax      ;ebx:=0
        mov edi,offset String
        fldz
        fcomip st,st(1) ;сравниваю число с нулем
        jnz @f
        mov byte ptr [edi],'0'
        jmp b0
@@:     jb @f
        mov al,'-'      ;если отрицательное вывожу знак минус
        stosb
        fchs            ;и получаю модуль числа
@@:     fstcw control   ;устанавливаю режим "округление к нулю"
        or control,0C00h
        fldcw control
        fld st          ;дублирую содержимое st(0) в st(1)
        frndint         ;округляю до целого содержимое st(0)
        fsub st(1),st   ;в st(1) остается дробная часть
        jnz @f
        mov al,'0'
        stosb
        jmp b3
@@:     call bcd2str
        fldz
        fcomip st,st(1)
        jz b0
        mov al,'.'
        stosb
        inc ebx               ; ebx:=1
        fmul y          ;умножаю дробную часть на 1.0e17
        call bcd2str
b0:     push 0
        push 0
        push offset String
        push 0
        call _imp__MessageBoxA@16
        retn
bcd2str proc
        fbstp temp
        mov ecx,9       ;в десятом байте информация о знаке числа
        test ebx,ebx; ebx = 0?
        jnz b1
@@:     cmp byte ptr [ecx-1+temp],0
        jnz b1
        loop @b         ;пропускаем незначащие (нулевые) разряды слева
b1:     mov al,byte ptr [ecx-1+temp];загружаем первую значащую пару разрядов
        cmp al,9        ;если в старшей тетраде 0 - пропустить старшую тетраду
        ja @f
        add al,30h      ;младшую тетраду переводим в ASCII
        stosb
        dec ecx
        jz b2
@@:     movzx ax,byte ptr [ecx-1+temp];распаковываем остальные разряды числа
        ror ax,4        ;выделяем старшую и младшую тетрады
        shr ah,4
        add ax,'00'     ;переводим в ASCII-код
        stosw
        loop @b
b2:     retn
bcd2str endp
x dt -123456789.987654321
control dw ? ;переменная под содержимое регистра CWR
temp dt ?    ;переменная под BCD
y dq 1.0e17  ;множитель
String db 30 dup (0)
end start

28.            jmp b3          ;переход есть, а метка отсутствует.

.686
.model flat
include windows.inc
includelib user32.lib
extern _imp__MessageBoxA@16:dword
.code
start:  fld x
    xchg ebx,eax
    mov edi,offset String
    fldz
    fcomip st,st(1) ;сравниваю число с нулем
    jnz @f
    mov byte ptr [edi],'0'
    jmp b0
@@: jb @f
    mov al,'-'      ;если отрицательное вывожу знак минус
    stosb
    fchs            ;и получаю модуль числа
@@: fstcw control   ;устанавливаю режим "округление к нулю"
    or control,0C00h
    fldcw control
    fld st          ;дублирую содержимое st(0) в st(1)
    frndint         ;округляю до целого содержимое st(0)
    fsub st(1),st   ;в st(1) остается дробная часть
    fldz
    fcomip st,st(1) ;сравниваю число с нулем
    jnz @f
    mov al,'0'
    stosb
    jmp b3
@@: call bcd2str
    fldz
b3: fcomip st,st(1)
    jz b0
    mov al,'.'
    stosb
    inc ebx
    fmul y      ;умножаю дробную часть на 1.0e17
    call bcd2str
b0: push 0
    push 0
    push offset String
    push 0
    call _imp__MessageBoxA@16
    retn
bcd2str proc
    fbstp temp
    mov ecx,9   ;в десятом байте информация о знаке числа
    test ebx,ebx
    jnz b1
@@:     cmp byte ptr [ecx-1+temp],0
    jnz b1
    loop @b         ;пропускаем незначащие (нулевые) разряды слева
b1: mov al,byte ptr [ecx-1+temp];загружаем первую значащую пару разрядов
        cmp al,9    ;если в старшей тетраде 0 - пропустить старшую тетраду
    ja @f
    add al,30h  ;младшую тетраду переводим в ASCII
    stosb
    dec ecx
    jz b2
@@:     movzx ax,byte ptr [ecx-1+temp];распаковываем остальные разряды числа
    ror ax,4        ;выделяем старшую и младшую тетрады
    shr ah,4
    add ax,'00' ;переводим в ASCII-код
    stosw
    loop @b
b2: retn
bcd2str endp
x dt -0.123456789;.987654321
control dw ? ;переменная под содержимое регистра CWR
temp dt ?    ;переменная под BCD
y dq 1.0e17  ;множитель
String db 30 dup (0)
end start